Использование, “новое” на структуре, выделяют его на "куче" или стеке?

Это также имеет значение, что Вы собираетесь сделать со значением после инициализации его. IL, используемый для [1 140]

Guid localVariable = new Guid(someString);

, отличается от IL, используемого для:

myInstanceOrStaticVariable = new Guid(someString);

, Кроме того, если значение используется в качестве промежуточного значения, например, аргумента вызову метода, вещи немного отличаются снова. Для показа всех этих различий вот, короткая тестовая программа. Это не показывает различие между статическими переменными и переменными экземпляра: IL отличался бы между [1 110] и stsfld, но это - все.

using System;

public class Test
{
    static Guid field;

    static void Main() {}
    static void MethodTakingGuid(Guid guid) {}


    static void ParameterisedCtorAssignToField()
    {
        field = new Guid("");
    }

    static void ParameterisedCtorAssignToLocal()
    {
        Guid local = new Guid("");
        // Force the value to be used
        local.ToString();
    }

    static void ParameterisedCtorCallMethod()
    {
        MethodTakingGuid(new Guid(""));
    }

    static void ParameterlessCtorAssignToField()
    {
        field = new Guid();
    }

    static void ParameterlessCtorAssignToLocal()
    {
        Guid local = new Guid();
        // Force the value to be used
        local.ToString();
    }

    static void ParameterlessCtorCallMethod()
    {
        MethodTakingGuid(new Guid());
    }
}

Вот IL для класса, исключая несоответствующие биты (такие как nops):

.class public auto ansi beforefieldinit Test extends [mscorlib]System.Object    
{
    // Removed Test's constructor, Main, and MethodTakingGuid.

    .method private hidebysig static void ParameterisedCtorAssignToField() cil managed
    {
        .maxstack 8
        L_0001: ldstr ""
        L_0006: newobj instance void [mscorlib]System.Guid::.ctor(string)
        L_000b: stsfld valuetype [mscorlib]System.Guid Test::field
        L_0010: ret     
    }

    .method private hidebysig static void ParameterisedCtorAssignToLocal() cil managed
    {
        .maxstack 2
        .locals init ([0] valuetype [mscorlib]System.Guid guid)    
        L_0001: ldloca.s guid    
        L_0003: ldstr ""    
        L_0008: call instance void [mscorlib]System.Guid::.ctor(string)    
        // Removed ToString() call
        L_001c: ret
    }

    .method private hidebysig static void ParameterisedCtorCallMethod() cil  managed    
    {   
        .maxstack 8
        L_0001: ldstr ""
        L_0006: newobj instance void [mscorlib]System.Guid::.ctor(string)
        L_000b: call void Test::MethodTakingGuid(valuetype [mscorlib]System.Guid)
        L_0011: ret     
    }

    .method private hidebysig static void ParameterlessCtorAssignToField() cil managed
    {
        .maxstack 8
        L_0001: ldsflda valuetype [mscorlib]System.Guid Test::field
        L_0006: initobj [mscorlib]System.Guid
        L_000c: ret 
    }

    .method private hidebysig static void ParameterlessCtorAssignToLocal() cil managed
    {
        .maxstack 1
        .locals init ([0] valuetype [mscorlib]System.Guid guid)
        L_0001: ldloca.s guid
        L_0003: initobj [mscorlib]System.Guid
        // Removed ToString() call
        L_0017: ret 
    }

    .method private hidebysig static void ParameterlessCtorCallMethod() cil managed
    {
        .maxstack 1
        .locals init ([0] valuetype [mscorlib]System.Guid guid)    
        L_0001: ldloca.s guid
        L_0003: initobj [mscorlib]System.Guid
        L_0009: ldloc.0 
        L_000a: call void Test::MethodTakingGuid(valuetype [mscorlib]System.Guid)
        L_0010: ret 
    }

    .field private static valuetype [mscorlib]System.Guid field
}

, Как Вы видите, существует много различных инструкций, используемых для вызова конструктора:

• newobj: Выделяет значение на стеке, вызывает параметризованного конструктора. Используемый для промежуточных значений, например, для присвоения на поле или использование в качестве аргумента метода.
• call instance: Использует уже выделенное место хранения (ли на стеке или не). Это используется в коде выше для присвоения локальной переменной. Если той же локальной переменной присваивают значение несколько раз с помощью нескольких new вызовы, она просто инициализирует данные поверх старого значения - она не делает , выделяют больше стекового пространства каждый раз.
• initobj: Использует уже выделенное место хранения и просто вытирает данные. Это используется для всех наших вызовов конструктора без параметров, включая тех, которые присваивают локальной переменной. Для вызова метода промежуточная локальная переменная эффективно представлена, и ее значение, вытертое [1 116].

я надеюсь, что это показывает, насколько сложный тема при проливании небольшого количества света на него одновременно. В [1 128] [приблизительно 1 128] концептуальные смыслы, каждый вызов к [1 117] выделяет место на стеке - но как мы видели, это не то, что действительно происходит даже на уровне IL. Я хотел бы выделить один особый случай. Возьмите этот метод:

void HowManyStackAllocations()
{
    Guid guid = new Guid();
    // [...] Use guid
    guid = new Guid(someBytes);
    // [...] Use guid
    guid = new Guid(someString);
    // [...] Use guid
}

, Который "логически" имеет 4 выделения стека - один для переменной, и один для каждого из три new вызовы - но на самом деле (для того определенного кода) стек только выделяется однажды, и затем то же место хранения снова используется.

РЕДАКТИРОВАНИЕ: Только, чтобы быть ясным, это только верно в некоторых случаях..., в частности, значение [1 119] не будет видимо, если Guid конструктор выдаст исключение, которое является, почему компилятор C# в состоянии снова использовать тот же слот стека. Посмотрите Eric Lippert сообщение в блоге на конструкции типа значения для получения дополнительной информации и случая, где это не делает , применяются.

я изучил много в записи этого ответа - попросите разъяснение, если какой-либо из него неясен!