Может ли командный файл указать, запущена ли программа? [Дубликат]

Предложение npocmaka использовать QPROCESS вместо TASKLIST велико, но его ответ настолько большой и сложный, что я чувствую себя обязанным опубликовать довольно упрощенную версию, которая, я думаю, решит проблему большинства неусовершенствованных пользователи:

QPROCESS "myprocess.exe">NUL
IF %ERRORLEVEL% EQU 0 ECHO "Process running"

. Вышеописанный код был протестирован в Windows 7 с пользователем с административными настройками.

На основе ответа vtrz и ответ Самуэля Ренкерта по другой теме я придумал следующий скрипт, который запускает только %EXEC_CMD%, если он еще не запущен :

@echo off
set EXEC_CMD="rsync.exe"
wmic process where (name=%EXEC_CMD%) get commandline | findstr /i %EXEC_CMD%> NUL
if errorlevel 1 (
    %EXEC_CMD% ...
) else (
    @echo not starting %EXEC_CMD%: already running.
)

Как уже было сказано, для этого требуются административные привилегии.

Просто отметив, что если ваше имя задачи действительно длинное, то оно не будет отображаться полностью в результате tasklist, поэтому может быть безопаснее (кроме локализации) проверять обратное.

Вариация этого ответа :

:: in case your task name is really long, check for the 'opposite' and find  the message when it's not there
tasklist /fi "imagename eq yourreallylongtasknamethatwontfitinthelist.exe" 2>NUL | find /I /N "no tasks are running">NUL
if "%errorlevel%"=="0" (
    echo Task Found
) else (
    echo Not Found Task
)

Ответ TrueY казался самым изящным решением, однако мне пришлось немного поработать, потому что я не понимал, что именно происходит. Позвольте мне прояснить ситуацию, надеюсь, сэкономить некоторое время для следующего человека.

Изменено TrueY Ответ:

::Change the name of notepad.exe to the process .exe that you're trying to track
::Process names are CASE SENSITIVE, so notepad.exe works but Notepad.exe does NOT
::Do not change IMAGENAME
::You can Copy and Paste this into an empty batch file and change the name of
::notepad.exe to the process you'd like to track
::Also, some large programs take a while to no longer show as not running, so
::give this batch a few seconds timer to avoid a false result!!

@echo off
SETLOCAL EnableExtensions

set EXE=notepad.exe

FOR /F %%x IN ('tasklist /NH /FI "IMAGENAME eq %EXE%"') DO IF %%x == %EXE% goto ProcessFound

goto ProcessNotFound

:ProcessFound

echo %EXE% is running
goto END
:ProcessNotFound
echo %EXE% is not running
goto END
:END
echo Finished!

В любом случае, я надеюсь, что это поможет. Я знаю, что иногда чтение партии / командной строки может иногда немного сбивать с толку, если вы новичок, как я.

Я не знаю, как это сделать со встроенным CMD, но если у вас есть grep , вы можете попробовать следующее:

tasklist /FI "IMAGENAME eq myApp.exe" | grep myApp.exe
if ERRORLEVEL 1 echo "myApp is not running"

Я предполагаю окна здесь. Таким образом, вам понадобится использовать WMI для получения этой информации. Ознакомьтесь с архивами Scripting Guy для большого количества примеров того, как использовать WMI из сценария.

Мне нравятся инструменты WMIC и TASKLIST, но они недоступны в домашних / базовых версиях окон. Другой способ - использовать команду QPROCESS, доступную почти на всех машинах Windows (для тех, которые имеют терминальные службы - Я думаю, что только выиграть XP без SP2, так что практически каждый компьютер Windows):

@echo off
:check_process
setlocal
if "%~1" equ "" echo pass the process name as forst argument && exit /b 1
:: first argument is the process you want to check if running
set process_to_check=%~1
:: QPROCESS can display only the first 12 symbols of the running process
:: If other tool is used the line bellow could be deleted
set process_to_check=%process_to_check:~0,12%

QPROCESS * | find /i "%process_to_check%" >nul 2>&1 && (
    echo process %process_to_check%  is running
) || (
    echo process %process_to_check%  is not running
)
endlocal

QPROCESS команда не так сильна, как TASKLIST и ограничена показом только 12 символов имени процесса, но следует учитывать, если TASKLIST недоступен.

Более простое использование, когда оно использует имя, если процесс как аргумент (суффикс .exe является обязательным в этот случай, когда вы передаете исполняемое имя):

@echo off
:check_process
setlocal
if "%~1" equ "" echo pass the process name as forst argument && exit /b 1
:: first argument is the process you want to check if running
:: .exe suffix is mandatory
set "process_to_check=%~1"


QPROCESS "%process_to_check%" >nul 2>&1 && (
    echo process %process_to_check%  is running
) || (
    echo process %process_to_check%  is not running
)
endlocal

Различие между двумя способами использования QPROCESS заключается в том, что QPROCESS * отобразит все процессы, в то время как QPROCESS some.exe будет фильтровать только процессы для текущий пользователь.

Использование WMI объектов через Windows-скрипт host exe вместо WMIC также является опцией. Он должен также запускаться на всех машинах Windows (исключая те, где отключен WSH но это редкий случай). Вот файл bat, который перечисляет все процессы через классы WMI и может использоваться вместо QPROCESS в приведенном выше скрипте (это гибрид jscript / bat и должен быть сохранен как .bat):

@if (@X)==(@Y) @end /* JSCRIPT COMMENT **


@echo off
cscript //E:JScript //nologo "%~f0"
exit /b

************** end of JSCRIPT COMMENT **/


var winmgmts = GetObject("winmgmts:\\\\.\\root\\cimv2");
var colProcess = winmgmts.ExecQuery("Select * from Win32_Process");
var processes =  new Enumerator(colProcess);
for (;!processes.atEnd();processes.moveNext()) {
    var process=processes.item();
    WScript.Echo( process.processID + "   " + process.Name );
}

И модификация, которая проверяет, запущен ли процесс:

@if (@X)==(@Y) @end /* JSCRIPT COMMENT **


@echo off
if "%~1" equ "" echo pass the process name as forst argument && exit /b 1
:: first argument is the process you want to check if running
set process_to_check=%~1

cscript //E:JScript //nologo "%~f0" | find /i "%process_to_check%" >nul 2>&1 && (
    echo process %process_to_check%  is running
) || (
    echo process %process_to_check%  is not running
)

exit /b

************** end of JSCRIPT COMMENT **/


var winmgmts = GetObject("winmgmts:\\\\.\\root\\cimv2");
var colProcess = winmgmts.ExecQuery("Select * from Win32_Process");
var processes =  new Enumerator(colProcess);
for (;!processes.atEnd();processes.moveNext()) {
    var process=processes.item();
    WScript.Echo( process.processID + "   " + process.Name );
}

Эти два параметра можно использовать на машинах, у которых нет TASKLIST.

Конечная техника использует MSHTA. Это будет работать на всех машинах Windows с XP и выше и не зависит от настроек хоста Windows Script. вызов MSHTA мог бы немного снизить производительность (опять же нужно сохранить как bat):

@if (@X)==(@Y) @end /* JSCRIPT COMMENT **
@echo off

setlocal
if "%~1" equ "" echo pass the process name as forst argument && exit /b 1
:: first argument is the process you want to check if running

set process_to_check=%~1


mshta "about:<script language='javascript' src='file://%~dpnxf0'></script>" | find /i "%process_to_check%" >nul 2>&1 && (
    echo process %process_to_check%  is running
) || (
    echo process %process_to_check%  is not running
)
endlocal
exit /b
************** end of JSCRIPT COMMENT **/


   var fso= new ActiveXObject('Scripting.FileSystemObject').GetStandardStream(1);


   var winmgmts = GetObject("winmgmts:\\\\.\\root\\cimv2");
   var colProcess = winmgmts.ExecQuery("Select * from Win32_Process");
   var processes =  new Enumerator(colProcess);
   for (;!processes.atEnd();processes.moveNext()) {
    var process=processes.item();
    fso.Write( process.processID + "   " + process.Name + "\n");
   }
   close();

Вы должны проверить имя родительского процесса, см. статью Code Project о решении, основанном на .NET ** .

Непрограммный способ проверить:

1. Запустить Cmd.exe
2. Запустить приложение (например, c:\windows\notepad.exe)
3. Проверить свойства Notepad.exe процесс в Process & nbsp; Explorer
4. Проверить родительский процесс (это показывает cmd.exe)

То же самое можно проверить, получив родительский имя процесса.

Еще одна возможность, с которой я столкнулся, с помощью grep :

tasklist /FI "IMAGENAME eq myapp.exe" 2>NUL | find /I /N "myapp.exe">NUL
if "%ERRORLEVEL%"=="0" echo Program is running

Не нужно сохранять дополнительный файл, поэтому я предпочитаю этот метод .

Я обычно выполняю следующую команду в приглашении cmd, чтобы проверить, работает ли мой program.exe или нет:

tasklist | grep program

TASKLIST | FINDSTR ProgramName || START "" "Path\ProgramName.exe"

Мне нравится решение Chaosmaster! Но я искал решение, которое не запускает другую внешнюю программу (например, find.exe или findstr.exe ). Поэтому я добавил идею из решения Мэтта Лэйси, которая создает также предотвращаемый файл temp. В конце я смог найти довольно простое решение, поэтому я поделился им ...

SETLOCAL EnableExtensions
set EXE=myprog.exe
FOR /F %%x IN ('tasklist /NH /FI "IMAGENAME eq %EXE%"') DO IF %%x == %EXE% goto FOUND
echo Not running
goto FIN
:FOUND
echo Running
:FIN

Это работает для меня красиво ...

Я использую PV.exe из http://www.teamcti.com/pview/prcview.htm , установленного в Program Files \ PV, с таким пакетным файлом:

@echo off
PATH=%PATH%;%PROGRAMFILES%\PV;%PROGRAMFILES%\YourProgram
PV.EXE YourProgram.exe >nul
if ERRORLEVEL 1 goto Process_NotFound
:Process_Found
echo YourProgram is running
goto END
:Process_NotFound
echo YourProgram is not running
YourProgram.exe
goto END
:END

В Windows вы можете использовать инструментарий управления Windows (WMI), чтобы гарантировать, что приложения с указанной командной строкой не запущены, например:

wmic process where (name="nmake.exe") get commandline | findstr /i /c:"/f load.mak" /c:"/f build.mak" > NUL && (echo THE BUILD HAS BEEN STARTED ALREADY! > %ALREADY_STARTED% & exit /b 1)