Преобразование элементов XML к атрибутам XML с помощью XSLT

Вот, вероятно, простое решение , который преобразует любые дочерние элементы ITEM к его атрибутам и воспроизведет все остальное, как, при преобразовании имен элементов к любым желаемым названиям атрибута:

<xsl:stylesheet version="1.0" 
 xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
 <xsl:output omit-xml-declaration="yes" indent="yes"/>
<!--                                              --> 
  <xsl:strip-space elements="*"/>

  <xsl:variable name="vrtfNameMapping">
    <item name="SERIALNUMBER" newName="serialNumber"/>
    <item name="LOCATION" newName="location"/>
    <item name="BARCODE" newName="barcode"/>
  </xsl:variable>
 <!--                                              --> 
  <xsl:variable name="vNameMapping" select=
  "document('')/*/xsl:variable[@name='vrtfNameMapping']"/>
<!--                                              --> 

  <xsl:template match="node()|@*">
    <xsl:copy>
      <xsl:apply-templates select="node()|@*"/>
    </xsl:copy>
  </xsl:template>
<!--                                              --> 
  <xsl:template match="ITEM/*">
    <xsl:attribute name=
     "{$vNameMapping/*[@name=name(current())]/@newName}">
      <xsl:value-of select="."/>
    </xsl:attribute>
  </xsl:template>
</xsl:stylesheet>

, когда вышеупомянутое преобразование применяется на предоставленный XML-документ :

<INVENTORY>
    <ITEM>
        <SERIALNUMBER>something</SERIALNUMBER>
        <LOCATION>something</LOCATION>
        <BARCODE>something</BARCODE>
    </ITEM>
</INVENTORY>

к требуемому результату приводят :

<INVENTORY>
   <ITEM serialNumber="something" location="something" barcode="something"/>
</INVENTORY>

Делают примечание следующее:

1. использование правило

2. идентификационных данных использование <xsl:strip-space elements="*"/>

3. использование переменной vrtfNameMapping без любого xxx:node-set() дополнительная функция.

4. то, что мы обрабатываем любое отображение между именем и newName, не только простым печатанием строчными литерами.

Эти два шаблона должны сделать it:-

<xsl:template match="ITEM">
   <ITEM serialNumber="{SERIALNUMBER}" location="{LOCATION}" barcode="{BARCODE}" />
</xsl:template>

<xsl:template match="INVENTORY">
   <INVENTORY>
      <xsl:apply-templates />
   </INVENTORY>
</xsl:template>

Это должно сделать это:

  <xsl:for-each select="//ITEM">
    <xsl:element name="ITEM">
      <xsl:attribute name="serialNumber">
        <xsl:value-of select="SERIALNUMBER"/>
      </xsl:attribute>
      <xsl:attribute name="location">
        <xsl:value-of select="LOCATION"/>
      </xsl:attribute>
      <xsl:attribute name="barcode">
        <xsl:value-of select="BARCODE"/>
      </xsl:attribute>
    </xsl:element>
  </xsl:for-each>

Или ярлык David использования:

<xsl:for-each select="//ITEM">
  <ITEM serialNumber="{SERIALNUMBER}" location="{LOCATION}" barcode="{BARCODE}"/>
</xsl:for-each>

Если Ваш источник похож на это:

<row><a>1</a><b>2</b></row>

и Вы хотите, чтобы это было похоже на это:

<row a="1" b="2" />

тогда этот XSLT должен работать:

<xsl:template match="row">
    <row a="{a}" b="{b}" />
</xsl:template>