Как я получаю результат команды в переменной в окнах?

Скромное для команда накопило некоторые интересные возможности за эти годы:

D:\> FOR /F "delims=" %i IN ('date /t') DO set today=%i
D:\> echo %today%
Sat 20/09/2008

Примечание, что "delims=" перезаписи пространство по умолчанию и разграничители табуляции так, чтобы вывод команды даты был пожран внезапно.

Для получения многострочного вывода это может все еще по существу быть острота (использующий переменную lf как разделитель в получающейся переменной):

REM NB:in a batch file, need to use %%i not %i
setlocal EnableDelayedExpansion
SET lf=-
FOR /F "delims=" %%i IN ('dir \ /b') DO if ("!out!"=="") (set out=%%i) else (set out=!out!%lf%%%i)
ECHO %out%

Для получения переданного по каналу выражения используйте ^|:

FOR /F "delims=" %%i IN ('svn info . ^| findstr "Root:"') DO set "URL=%%i"

Для получения текущего каталога можно использовать это:

CD > tmpFile
SET /p myvar= < tmpFile
DEL tmpFile
echo test: %myvar%

Это использует временный файл, хотя, таким образом, это не является самым симпатичным, но это, конечно, работает! 'CD' помещает текущий каталог в 'tmpFile', 'НАБОР' загружает содержание tmpFile.

Вот решение для нескольких строк с "массивом":

@echo off

rem ---------
rem Obtain line numbers from the file
rem ---------

rem This is the file that is being read: You can replace this with %1 for dynamic behaviour or replace it with some command like the first example i gave with the 'CD' command.
set _readfile=test.txt

for /f "usebackq tokens=2 delims=:" %%a in (`find /c /v "" %_readfile%`) do set _max=%%a
set /a _max+=1
set _i=0
set _filename=temp.dat

rem ---------
rem Make the list
rem ---------

:makeList
find /n /v "" %_readfile% >%_filename%

rem ---------
rem Read the list
rem ---------

:readList
if %_i%==%_max% goto printList

rem ---------
rem Read the lines into the array
rem ---------
for /f "usebackq delims=] tokens=2" %%a in (`findstr /r "\[%_i%]" %_filename%`) do set _data%_i%=%%a
set /a _i+=1
goto readList

:printList
del %_filename%
set _i=1
:printMore
if %_i%==%_max% goto finished
set _data%_i%
set /a _i+=1
goto printMore

:finished

, Но Вы могли бы хотеть рассмотреть перемещение в другую более мощную оболочку или создать приложение для этого материала. Это расширяет возможности пакетных файлов вполне немного.

необходимо использовать эти SET команда с параметром /P и направить вывод к нему. Например, см. http://www.ss64.com/nt/set.html . Будет работать на CMD, не уверенный в.BAT файлах

От комментария до этого сообщения:

, Что ссылка имеет команду "112", которая говорит, это установит _MyVar на первую строку от MyFilename.txt. Это могло использоваться в качестве" myCmd > tmp.txt" с" set /P myVar=<tmp.txt". Но это только получит первую строку вывода, не всего вывода

Пример для установки в "V" переменная среды новый файл

FOR /F %I IN ('DIR *.* /O:D /B') DO SET V=%I

в пакетном файле необходимо использовать двойной префикс в переменной цикла:

FOR /F %%I IN ('DIR *.* /O:D /B') DO SET V=%%I

Если Вы ищете решение, предоставленное в Используя результат команды как аргумент в ударе?

затем вот код:

@echo off
if not "%1"=="" goto get_basename_pwd
for /f "delims=X" %%i in ('cd') do call %0 %%i
for /f "delims=X" %%i in ('dir /o:d /b') do echo %%i>>%filename%.txt
goto end

:get_basename_pwd
set filename=%~n1

:end

• Это назовет себя с результатом команды CD, то же как pwd.
• Строковое извлечение на параметрах возвратит имя файла/папку.
• Получают содержание этой папки и добавляют к filename.txt

[Кредиты] : Благодаря всем другим ответам и некоторому рытью на команды Windows XP страница.

Можно получить весь вывод в одной переменной, но строки будут разделены символом по Вашему выбору (# в примере ниже) вместо фактического CR-LF.

@echo off
setlocal EnableDelayedExpansion
for /f "delims=" %%i in ('dir /b') do (
    if "!DIR!"=="" (set DIR=%%i) else (set DIR=!DIR!#%%i)
)
echo directory contains:
echo %DIR%

Вторая версия, если необходимо распечатать содержание линию за линией. Это берет advanted того, что не будет дублирующихся строк вывода от "dir/b", таким образом, он не сможет работать в общем случае.

@echo off
setlocal EnableDelayedExpansion
set count=0
for /f "delims=" %%i in ('dir /b') do (
    if "!DIR!"=="" (set DIR=%%i) else (set DIR=!DIR!#%%i)
    set /a count = !count! + 1
)

echo directory contains:
echo %DIR%

for /l %%c in (1,1,%count%) do (
    for /f "delims=#" %%i in ("!DIR!") do (
        echo %%i
        set DIR=!DIR:%%i=!
    )
)

См. этот http://technet.microsoft.com/en-us/library/bb490982.aspx , который объясняет, что можно сделать с выводом команды.