Свойство “Tag” Vb6, эквивалентное в ASP.NET?

Нет, нет никакого прямого эквивалента, но если Вы используете v3.5 Платформы, можно добавить эту функциональность довольно легко с помощью дополнительного метода. Например:

Imports System.Runtime.CompilerServices

Public Module Extensions
  <Extension()> _
  Public Sub SetTag(ByVal ctl As Control, ByVal tagValue As String)
    If SessionTagDictionary.ContainsKey(TagName(ctl)) Then
        SessionTagDictionary(TagName(ctl)) = tagValue
    Else
        SessionTagDictionary.Add(TagName(ctl), tagValue)
    End If
  End Sub

  <Extension()> _
  Public Function GetTag(ByVal ctl As Control) As String
    If SessionTagDictionary.ContainsKey(TagName(ctl)) Then
        Return SessionTagDictionary(TagName(ctl))
    Else
        Return String.Empty
    End If
  End Function

  Private Function TagName(ByVal ctl As Control) As String
    Return ctl.Page.ClientID & "." & ctl.ClientID
  End Function

  Private Function SessionTagDictionary() As Dictionary(Of String, String)
    If HttpContext.Current.Session("TagDictionary") Is Nothing Then
        SessionTagDictionary = New Dictionary(Of String, String)
        HttpContext.Current.Session("TagDictionary") = SessionTagDictionary
    Else
        SessionTagDictionary = DirectCast(HttpContext.Current.Session("TagDictionary"), _ 
          Dictionary(Of String, String))
    End If
  End Function
End Module

Затем на Ваших страницах ASP.NET сначала принесите свои расширения в объем, например:

Imports WebApplication1.Extensions

... и затем используйте его Ваши средства управления, как желаемый:

TextBox1.SetTag("Test")

Label1.Text = TextBox1.GetTag

БОЛЕЕ ПОЗДНЕЕ РЕДАКТИРОВАНИЕ: и если Вы действительно, действительно не хотите хранить свои теги в объекте Сессии, возможно наполнить их в Ваше Состояние отображения вместо этого. Это будет, конечно, означать, что Ваши теги будут выставлены в разметке страницы, отправленной пользователю (хотя в запутываемой форме), и, к сожалению, что некоторое отражение-fu требуется, так как свойство ViewState Страницы отмечено, как 'защищено' по некоторым причинам.

Так, этот код нужно в значительной степени рассмотреть в целях развлечений только, если Вам на самом деле не нравится повышать брови во время обзоров кода:

<Extension()> _
  Public Sub SetTag(ByVal ctl As Control, ByVal tagValue As String)
    ViewState.Add(ctl.ID & "_Tag", tagValue)
  End Sub

<Extension()> _
  Public Function GetTag(ByVal ctl As Control) As String
    Return ViewState(ctl.ID & "_Tag")
  End Function

Private Function ViewState() As Web.UI.StateBag
    Return HttpContext.Current.Handler.GetType.InvokeMember("ViewState", _
                Reflection.BindingFlags.GetProperty + _
                Reflection.BindingFlags.Instance + _
                Reflection.BindingFlags.NonPublic, _
                Nothing, HttpContext.Current.CurrentHandler, Nothing)
End Function

ЗАКЛЮЧИТЕЛЬНОЕ РЕДАКТИРОВАНИЕ (я обещаю...). И вот способ избавиться от отражения: во-первых, создайте новый класс, чтобы выставить свойство ViewState с применимым уровнем защиты, затем изменить Ваш Код - Позади (.aspx.vb) классов для наследования этого вместо сети. UI.Page, например:

Public Class PageEx
  Inherits System.Web.UI.Page

  Friend ReadOnly Property ViewStateEx() As Web.UI.StateBag
    Get
        Return MyBase.ViewState
    End Get
  End Property
End Class

Теперь, в Вашем модуле расширений, можно получить доступ к этому недавно определенному свойству как:

Private Function ViewState() As Web.UI.StateBag
  Return DirectCast(HttpContext.Current.Handler, PageEx).ViewStateEx
End Function

Все еще определенный взлом, но намного более приемлемый, чем использование отражения...