Есть ли существует способ изменить значок папки Windows с помощью сценария Perl?

Вы точно можете сделать это с помощью Perl. Windows управляет значками каталогов с помощью скрытого системного файла Dekstop.ini в каждой папке. Содержимое выглядит примерно так:

 [.ShellClassInfo]
 IconFile=%SystemRoot%\system32\SHELL32.dll
 IconIndex=41

В Windows XP (и я предполагаю, что в других системах) значок 41 представляет собой дерево. Windows требует, чтобы этот файл был явно задан как системный файл, чтобы он работал, это означает, что нам нужно копаться в Win32API :: File , чтобы создать его:

 #!/usr/bin/perl
 use strict;
 use warnings;

 use Win32API::File qw(createFile WriteFile fileLastError CloseHandle);

 my $file = createFile(
      'Desktop.ini',
      {
           Access     => 'w',        # Write access
           Attributes => 'hs',       # Hidden system file
           Create     => 'tc',       # Truncate/create
      }
 ) or die "Can't create Desktop.ini - " . fileLastError();

 WriteFile(
      $file,
      "[.ShellClassInfo]\r\n" .
      "IconFile=%SystemRoot%\\system32\\SHELL32.dll\r\n" .
      "IconIndex=41\r\n",
      0, [], []
 ) or die "Can't write Desktop.ini - " . fileLastError();

 CloseHandle($file) or die "Can't close Desktop.ini - " . fileLastError();

Если вы запустите приведенный выше код, он должен установить значок для текущего каталога в виде дерева. Возможно, вам потребуется обновить список каталогов, прежде чем проводник обнаружит изменение.

Теперь, когда у нас есть способ изменить значки, теперь мы можем просто пройтись по всему диску и изменить каждую папку, соответствующую нашему шаблону. Мы можем сделать это довольно легко с помощью File :: Find , или одна из его альтернатив (например, File :: Find :: Rule или File :: Next ):

 #!/usr/bin/perl
 use strict;
 use warnings;
 use File::Find qw(find);
 use Win32API::File qw(createFile WriteFile fileLastError CloseHandle);

 my $topdir = $ARGV[0] or die "Usage: $0 path\n";

 find( \&changeIcon, $topdir);

 sub changeIcon {
     return if not /documents$/i;   # Skip non-documents folders
     return if not -d;              # Skip non-directories.

     my $file = createFile(
         "$_\\Desktop.ini",
         {
              Access     => 'w',        # Write access
              Attributes => 'hs',       # Hidden system file
              Create     => 'tc',       # Truncate/create
         }
     ) or die "Can't create Desktop.ini - " . fileLastError();

     WriteFile(
         $file,
         "[.ShellClassInfo]\r\n" .
         "IconFile=%SystemRoot%\\system32\\SHELL32.dll\r\n" .
         "IconIndex=41\r\n",
         0, [], []
     ) or die "Can't write Desktop.ini - " . fileLastError();

     CloseHandle($file) or die "Can't close Desktop.ini - " . fileLastError();
 }

К сожалению, я только что обнаружил, что значок изменяется только , если в каталоге в настоящее время или когда-то был значок ... В самом каталоге явно установлен атрибут, который заставляет Windows искать файл Desktop.ini , но я не могу понять, что это такое. Таким образом, вышеуказанное решение является неполным; нам также необходимо найти и исправить атрибуты в каталоге, в который мы добавляем значок.

Paul

Чтобы обновить значок, вам нужно будет вызвать вуду SHChangeNotify (пример C ++, но вы поняли идею):

int imageIndex = Shell_GetCachedImageIndexW(wPath, GetSyncFolderIconIndex(), 0);
if (imageIndex != -1)
{
    // If we don't do this, and we EVER change our icon, Explorer will likely keep
    // using the old one that it's already got in the system cache.
    SHChangeNotify(SHCNE_UPDATEIMAGE, SHCNF_DWORD | SHCNF_FLUSHNOWAIT, &imageIndex, NULL);
}
SHChangeNotify(SHCNE_UPDATEITEM, SHCNF_PATHW | SHCNF_FLUSHNOWAIT, wPath, NULL);