Заглушка является простым поддельным объектом. Это просто гарантирует, что тест проходит гладко.
Насмешка - умная заглушка. Вы проверяете, что ваш тест проходит через него.
Я так и не нашел идеального решения для этого. Net :: SNMP :: Message (часть Net :: SNMP ) может допускать это, но, похоже, не имеет публично определенного интерфейса, и ни один интерфейс Net :: SNMP не казался особенно актуальным. NSNMP ближе всего к духу того, что я искал, но он хрупкий и не работал с моим пакетом из коробки, и если я собираюсь поддерживать хрупкий код, он будет моим собственный хрупкий код =).
Mon :: SNMP также приблизился к тому, что я искал, но он тоже был сломан из коробки. Похоже, что он был заброшен с последним выпуском в 2001 году и последним выпуском CPAN разработчика в 2002 году. Я не осознавал этого в то время, но теперь думаю, что он сломан из-за изменения интерфейса Convert :: BER модуль, который он использует.
Mon :: SNMP указал мне на Convert :: BER . Несколько тысяч считываний Convert :: BER POD, источника Mon :: SNMP и RFC 1157 (особенно 4.1.6, «Trap-PDU») позже, и я придумал этот код в качестве доказательства концепции делать то, что я хотел. Это просто доказательство концепции (по причинам, которые я подробно расскажу после кода), поэтому он может быть не идеальным, но я подумал, что он может стать полезным справочником для будущих специалистов по Perl, работающих в этой области, поэтому вот оно:
#!/usr/bin/perl
use Convert::BER;
use Convert::BER qw(/^(\$|BER_)/);
my $ber = Convert::BER->new();
# OID I want to add to the trap if not already present
my $snmpTrapAddress = '1.3.6.1.6.3.18.1.3';
# this would be from the incoming socket in production
my $source_ip = '10.137.54.253';
# convert the octets into chars to match SNMP standard for IPs
my $source_ip_str = join('', map { chr($_); } split(/\./, $source_ip));
# Read the binary trap data from STDIN or ARGV. Normally this would
# come from the UDP receiver
my $d = join('', <>);
# Stuff my trap data into $ber
$ber->buffer($d);
print STDERR "Original packet:\n";
$ber->dump();
# Just decode the first two fields so we can tell what version we're dealing with
$ber->decode(
SEQUENCE => [
INTEGER => \$version,
STRING => \$community,
BER => \$rest_of_trap,
],
) || die "Couldn't decode packet: ".$ber->error()."\n";
if ($version == 0) {
#print STDERR "This is a version 1 trap, proceeding\n";
# decode the PDU up to but not including the VARBINDS
$rest_of_trap->decode(
[ SEQUENCE => BER_CONTEXT | BER_CONSTRUCTOR | 0x04 ] =>
[
OBJECT_ID => \$enterprise_oid,
[ STRING => BER_APPLICATION | 0x00 ] => \$agentaddr,
INTEGER => \$generic,
INTEGER => \$specific,
[ INTEGER => BER_APPLICATION | 0x03 ] => \$timeticks,
SEQUENCE => [ BER => \$varbind_ber, ],
],
) || die "Couldn't decode packet: ".$extra->error()."\n";;
# now decode the actual VARBINDS (just the OIDs really, to decode the values
# We'd have to go to the MIBs, which I neither want nor need to do
my($r, $t_oid, $t_val, %varbinds);
while ($r = $varbind_ber->decode(
SEQUENCE => [
OBJECT_ID => \$t_oid,
ANY => \$t_val,
], ))
{
if (!$r) {
die "Couldn't decode SEQUENCE: ".$extra->error()."\n";
}
$varbinds{$t_oid} = $t_val;
}
if ($varbinds{$snmpTrapAddress} || $varbinds{"$snmpTrapAddress.0"}) {
# the original trap already had the data, just print it back out
print $d;
} else {
# snmpTrapAddress isn't present, create a new object and rebuild the packet
my $new_trap = new Convert::BER;
$new_trap->encode(
SEQUENCE => [
INTEGER => $version,
STRING => $community,
[ SEQUENCE => BER_CONTEXT | BER_CONSTRUCTOR | 0x04 ] =>
[
OBJECT_ID => $enterprise_oid,
[ STRING => BER_APPLICATION | 0x00 ] => $agentaddr,
INTEGER => $generic,
INTEGER => $specific,
[ INTEGER => BER_APPLICATION | 0x03 ] => $timeticks,
SEQUENCE => [
BER => $varbind_ber,
# this next oid/val is the only mod we should be making
SEQUENCE => [
OBJECT_ID => "$snmpTrapAddress.0",
[ STRING => BER_APPLICATION | 0x00 ] => $source_ip_str,
],
],
],
],
);
print STDERR "New packet:\n";
$new_trap->dump();
print $new_trap->buffer;
}
} else {
print STDERR "I don't know how to decode non-v1 packets yet\n";
# send back the original packet
print $d;
}
Итак , это оно. Вот кикер. Я поймал их на слове, что они не получают IP-адрес исходного отправителя в ловушке. Работая с этим примером, я обнаружил, что, по крайней мере, в примере, который они мне дали, исходный IP-адрес был в поле agent-addr в ловушке. Показав им это и где в API инструмента раскрыто их использование, они ушли, чтобы попытаться внести изменения со своей стороны. Я использую приведенный выше код на тот момент, когда они просят меня о чем-то, что мне действительно нужно, чтобы избавиться от пакета, но пока что приведенное выше останется не прошедшим строгую проверку доказательством концептуального кода. Надеюсь, когда-нибудь это кому-нибудь поможет.
Обязательно посмотрите SNMP_Session.
http://code.google.com/p/snmp-session/
Обязательно следуйте ссылкам на старый сайт распространения, на котором есть несколько примеров.
Я в основном прошел по тому же пути. Mon :: SNMP, Convert :: BER, TCP / IP Illustrated и т.д .. SNMP_Session - единственное, что мне удалось заставить работать. Под работой я имею в виду прием ловушек SNMP на UDP-порту 162 и декодирование их в строковые эквиваленты для ведения журнала, не изобретая заново несколько колес. Я использую только функцию ловушки приема, но думаю, что она может делать то, что вы хотите.
Это в Google Code, но не в CPAN, поэтому найти его немного сложно.