Как я реализую таблицы отправки в Perl?

Во-первых, проверка равенства строк в Perl - это eq , а не == .

Если у вас есть методы для выполнения работы, скажем, с именем bit и ftp,

my %proc = (
    bit => \&bit,
    ftp => \&ftp,
);

my $proc = $proc{$trans_type};
$proc->() if defined $proc;

Вы можете использовать для этого хеш ...

1. Пусть каждый метод передачи регистрирует себя в хеше. $ MyApp :: TransferManager :: МЕТОДЫ {ftp} = \ & do_ftp; sub do_ftp {...} 1;

2. Каждый метод передачи использует согласованный API. Может быть, это просто функция, или это может быть интерфейс объекта.

3. Вызов передачи через хэш.

    sub do_transfer {
    # ...
    мой $ sub = $ MyApp :: TransferManager :: МЕТОДЫ {$ метод}
    или квакать "Неизвестный метод передачи $ method";
    $ sub -> ($ arg1, $ arg2, ...);
    # ...
   }
   

Кстати: метод регистрации OO будет выглядеть примерно так:

package MyApp::TransferManager;
use Carp;
use strict;

my %registered_method;

sub register {
    my ($class, $method, $sub) = @_;

    exists $registered_method{$method}
        and croak "method $method already registered";

    $registered_method{$method} = $sub;
}

# ...

1;

(Ни один из этих кодов не протестирован; прошу прощения за пропущенные точки с запятой)

Правильная конструкция здесь - завод. Посмотрите, как с этим справляется DBI . В итоге вы получите класс TransferAgent , который создает один из любого количества классов TransferAgent :: * . Очевидно, вам понадобится больше проверок ошибок, чем предоставляет реализация ниже. Использование подобной фабрики означает, что вы можете добавлять новые типы агентов передачи без необходимости добавлять или изменять какой-либо код.

TransferAgent.pm - фабричный класс:

package TransferAgent;

use strict;
use warnings;

sub connect {
    my ($class, %args) = @_;

    require "$class/$args{type}.pm";

    my $ta = "${class}::$args{type}"->new(%args);
    return $ta->connect;
}

1;

TransferAgent / Base.pm - содержит базу функциональность класса TransferAgent :: * :

package TransferAgent::Base;

use strict;
use warnings;

use Carp;

sub new {
    my ($class, %self) = @_;
    $self{_files_transferred} = [];
    $self{_bytes_transferred} = 0;
    return bless \%self, $class;
}

sub files_sent { 
    return wantarray ?  @{$_[0]->{_files_sent}} : 
        scalar @{$_[0]->{_files_sent}};
}

sub files_received { 
    return wantarray ?  @{$_[0]->{_files_recv}} : 
        scalar @{$_[0]->{_files_recv}};
}

sub cwd    { return $_[0]->{_cwd}       }
sub status { return $_[0]->{_connected} }

sub _subname {
    return +(split "::", (caller 1)[3])[-1];
}

sub connect    { croak _subname, " is not implemented by ", ref $_[0] }
sub disconnect { croak _subname, " is not implemented by ", ref $_[0] }
sub chdir      { croak _subname, " is not implemented by ", ref $_[0] }
sub mode       { croak _subname, " is not implemented by ", ref $_[0] }
sub put        { croak _subname, " is not implemented by ", ref $_[0] }
sub get        { croak _subname, " is not implemented by ", ref $_[0] }
sub list       { croak _subname, " is not implemented by ", ref $_[0] }

1;

TransferAgent / FTP.pm - реализует (фиктивный) FTP-клиент:

package TransferAgent::FTP;

use strict;
use warnings;

use Carp;

use base "TransferAgent::Base";

our %modes = map { $_ => 1 } qw/ascii binary ebcdic/;

sub new {
    my $class = shift;
    my $self  = $class->SUPER::new(@_);
    $self->{_mode} = "ascii";
    return $self;
}

sub connect    { 
    my $self = shift;
    #pretend to connect
    $self->{_connected} = 1;
    return $self;
}

sub disconnect {
    my $self = shift;
    #pretend to disconnect
    $self->{_connected} = 0;
    return $self;
}

sub chdir { 
    my $self = shift;
    #pretend to chdir
    $self->{_cwd} = shift;
    return $self;
}

sub mode {
    my ($self, $mode) = @_;

    if (defined $mode) {
        croak "'$mode' is not a valid mode"
            unless exists $modes{$mode};
        #pretend to change mode
        $self->{_mode} = $mode;
        return $self;
    }

    #return current mode
    return $self->{_mode};
}

sub put {
    my ($self, $file) = @_;
    #pretend to put file
    push @{$self->{_files_sent}}, $file;
    return $self;
}

sub get {
    my ($self, $file) = @_;
    #pretend to get file
    push @{$self->{_files_recv}}, $file;
    return $self;
}

sub list {
    my $self = shift;
    #pretend to list remote files
    return qw/foo bar baz quux/;
}

1;

script.pl - как использовать TransferAgent:

#!/usr/bin/perl

use strict;
use warnings;

use TransferAgent;

my $ta = TransferAgent->connect(
    type     => "FTP",
    host     => "foo",
    user     => "bar",
    password => "baz",
);

print "files to get: ", join(", ", $ta->list), "\n";
for my $file ($ta->list) {
    $ta->get($file);
}
print "files gotten: ", join(", ", $ta->files_received), "\n";

$ta->disconnect;

I have several examples in Mastering Perl in the sections on dynamic subroutines.

См. Реализация таблиц диспетчеризации и обработка MJD таблиц диспетчеризации в HOP .

OO было бы излишним. Мое решение, вероятно, будет выглядеть примерно так:

sub ftp_transfer { ... }
sub bit_transfer { ... }
my $transfer_sub = { 'ftp' => \&ftp_transfer, 'bit' => \&bit_transfer, ... };
...
sub upload_file {
    my ($file, ...) = @_;
    ...
    $transfer_sub->{$file->{trans_type}}->(...);
}

Вы сказали, что сначала он будет использовать FTP, а позже перейдет к другим методам передачи. Я бы не стал называть «элегантным», пока вам действительно не понадобится добавить вторую или третью технологию. Этот второй метод передачи может никогда не потребоваться. : -)

Если вы хотите сделать это как «научный проект», тогда отлично.

Я устал видеть объектно-ориентированные шаблоны проектирования, усложняющие решения проблем, которые никогда не возникают.

Оберните первый метод передачи в метод uploadFile. Добавьте if, то else для второго метода. Получите элегантность и проведите рефакторинг третьего метода. К тому времени у вас будет достаточно примеров, так что ваше решение, вероятно, будет довольно общим.

Конечно, я хочу сказать, что второй и третий методы могут никогда не потребоваться.