Выполнение Word Mail Merge

Question

Выполнение Word Mail Merge

Просто умножьте значения RGB на сумму, которой Вы хотите изменить уровень. Если один из цветов уже в макс. значении, то Вы не можете сделать его немного более ярким (использующий математику HSV так или иначе.)

Это дает тот же самый результат с намного меньшим количеством математики как переключающийся на HSV и затем изменяющий V. Это дает тот же результат как переключающийся на HSL и затем изменяющий L, пока Вы не хотите начинать терять насыщенность.

8

vba excel-vba ms-word excel

задан Community 9 July 2018 в 19:34

1 ответ

Другие вопросы по тегам:

vba excel-vba ms-word excel

Похожие вопросы:

score 18 · Accepted Answer

If your Word document is already configured with the merge fields, and you are running the macro from the workbook that contains the data you want to merge into the Word document, then try this:

Sub RunMerge()

    Dim wd As Object
    Dim wdocSource As Object

    Dim strWorkbookName As String

    On Error Resume Next
    Set wd = GetObject(, "Word.Application")
    If wd Is Nothing Then
        Set wd = CreateObject("Word.Application")
    End If
    On Error GoTo 0

    Set wdocSource = wd.Documents.Open("c:\test\WordMerge.docx")

    strWorkbookName = ThisWorkbook.Path & "\" & ThisWorkbook.Name

    wdocSource.MailMerge.MainDocumentType = wdFormLetters

    wdocSource.MailMerge.OpenDataSource _
            Name:=strWorkbookName, _
            AddToRecentFiles:=False, _
            Revert:=False, _
            Format:=wdOpenFormatAuto, _
            Connection:="Data Source=" & strWorkbookName & ";Mode=Read", _
            SQLStatement:="SELECT * FROM `Sheet1$`"

    With wdocSource.MailMerge
        .Destination = wdSendToNewDocument
        .SuppressBlankLines = True
        With .DataSource
            .FirstRecord = wdDefaultFirstRecord
            .LastRecord = wdDefaultLastRecord
        End With
        .Execute Pause:=False
    End With

    wd.Visible = True
    wdocSource.Close SaveChanges:=False

    Set wdocSource = Nothing
    Set wd = Nothing

End Sub