Управление версиями базы данных в установленных приложениях с помощью Delphi

У меня есть запись в блоге о том, как управление версиями базы данных dbisam и сервер sql .

Важные части:

Поскольку dbisam не поддерживает представления, номер версии сохраняется (вместе с кучей другой информации) в ini файл в каталоге базы данных.

У меня есть модуль данных, TdmodCheckDatabase. Это имеет Компонент TdbisamTable для каждой таблицы в базе данных. Компонент таблицы содержит все поля в таблице и обновляется всякий раз, когда таблица изменено.

Чтобы внести изменения в базу данных, был использован следующий процесс:

1. Увеличить номер версии в приложении
2. Внести и протестировать изменения в БД.
3. Обновить затронутые таблицы в TdmodCheckDatabase
4. При необходимости (редко) добавить дополнительные запросы на обновление в TdmodCheckDatabase. Например, чтобы установить значения новых полей, или добавить новые строки данных.
5. Создайте единичный скрипт CreateDatabase, используя предоставленную базу данных. tools.
6. Обновить модульные тесты для соответствия новой базе данных

Когда приложение запущено, оно с помощью следующего процесса

1. . Если база данных не найдена, запустите модуль CreateDatabase, а затем выполните шаг 3
2. Получить текущий номер версии из ini-файла базы данных
3. Если он меньше ожидаемого номера версии, тогда Запустите CreateDatabase (для создания любых новых таблиц) Проверьте каждый компонент таблицы в TdmodCheckDatabase Применить любые изменения таблицы запускать любые сценарии обновления вручную
4. Обновить номер версии в ini-файле базы данных

Пример кода:

class procedure TdmodCheckDatabase.UpgradeDatabase(databasePath: string; currentVersion, newVersion: integer);
var
module: TdmodCheckDatabase;
f: integer;
begin
module:= TdmodCheckDatabase.create(nil);
try
  module.OpenDatabase( databasePath );

  for f:= 0 to module.ComponentCount -1  do
  begin
    if module.Components[f] is TDBISAMTable then
    begin
      try
        // if we need to upgrade table to dbisam 4
        if currentVersion <= DB_VERSION_FOR_DBISAM4 then
          TDBISAMTable(module.Components[f]).UpgradeTable;

        module.UpgradeTable(TDBISAMTable(module.Components[f]));
      except
       // logging and error stuff removed
      end;
    end;
  end;

  for f:= currentVersion + 1 to newVersion do
    module.RunUpgradeScripts(f);

  module.sqlMakeIndexes.ExecSQL; // have to create additional indexes manually
 finally
  module.DBISAMDatabase1.Close;
  module.free;
end;
end;


procedure TdmodCheckDatabase.UpgradeTable(table: TDBISAMTable);
var
 fieldIndex: integer;
 needsRestructure: boolean;
 canonical: TField;
begin
 needsRestructure:= false;

 table.FieldDefs.Update;

 // add any new fields to the FieldDefs
 if table.FieldDefs.Count < table.FieldCount then
 begin
   for fieldIndex := table.FieldDefs.Count to table.Fields.Count -1 do
   begin
     table.FieldDefs.Add(fieldIndex + 1, table.Fields[fieldIndex].FieldName, table.Fields[fieldIndex].DataType, table.Fields[fieldIndex].Size, table.Fields[fieldIndex].Required);
   end;
   needsRestructure:= true;
 end;

 // make sure we have correct size for string fields
 for fieldIndex := 0 to table.FieldDefs.Count -1 do
 begin
   if (table.FieldDefs[fieldIndex].DataType = ftString) then
   begin
     canonical:= table.FindField(table.FieldDefs[fieldIndex].Name);
     if assigned(canonical) and (table.FieldDefs[fieldIndex].Size <> canonical.Size) then
   begin
     // field size has changed
     needsRestructure:= true;
     table.FieldDefs[fieldIndex].Size:= canonical.Size;
   end;
   end;
 end;

 if needsRestructure then
   table.AlterTable(); // upgrades table using the new FieldDef values
end;

procedure TdmodCheckDatabase.RunUpgradeScripts(newVersion: integer);
begin
 case newVersion of
   3: sqlVersion3.ExecSQL;
   9: sqlVersion9.ExecSQL;
   11: begin  // change to DBISAM 4
         sqlVersion11a.ExecSQL;
         sqlVersion11b.ExecSQL;
         sqlVersion11c.ExecSQL;
         sqlVersion11d.ExecSQL;
         sqlVersion11e.ExecSQL;
       end;
   19: sqlVersion19.ExecSQL;
   20: sqlVersion20.ExecSQL;
 end;
end;