Как переключиться между несколькими конфигурациями энергии с командой или локальными vimrc файлами?

В Резюме

Есть несколько способов сделать это, большинство из которых было предложено, но я подумал, что резюмирую их двумя дополнительными:

• Per-directory vimrc - имеет тот недостаток, что Vim должен запускаться в правильный каталог: если ваш проект находится в ~ / project1 и у вас есть ~ / project1 / .vim.custom и выполните cd ~; vim project1 / file.c , пользовательские настройки не будут найдены.
• Модели - очень эффективны, но имеет недостаток, заключающийся в необходимости добавлять их ко всем файлам (и не забывать добавлять их в новые файлы).
• Автокоманды, специфичные для каталога - это очень эффективно
• Поиск в файле определенного заголовка (см. ниже) - это это тот, который я использовал чаще всего в прошлом, когда работал с разными компаниями или над четко названными проектами
• . vimrc для каждого каталога, который проверяется при открытии файла (см. ниже). Еще один, довольно простой в реализации, особенно если код вашего проекта находится в одном месте.

Поиск заголовка

Во многих организациях есть стандартный заголовок (с уведомлением об авторских правах, названием проекта и т. Д.) В вверху каждого исходного файла. В этом случае вы можете заставить Vim автоматически сканировать первые (например) 10 строк файла в поисках ключевого слова. Если он его найдет, он может изменить ваши настройки. Я' мы изменили его, чтобы сделать его проще, чем форма, которую я использую (которая выполняет множество других функций), но создаем ~ / .vim / after / filetype.vim (если у вас его еще нет) и добавьте что-нибудь вроде этого:

au FileType * call <SID>ConfigureFiletypes(expand("<amatch>"))

" List of file types to customise
let s:GROUPNAMETypes = ['c', 'cpp', 'vhdl', 'c.doxygen']

func! <SID>CheckForGROUPNAMECode()
    " Check if any of the first ten lines contain "GROUPNAME".

    " Read the first ten lines into a variable
    let header = getline(1)
    for i in range(2, 10)
        let header = header . getline(i)
    endfor

    if header =~ '\<GROUPNAME\>'
        " Change the status line to make it clear which
        " group we're using
        setlocal statusline=%<%f\ (GROUPNAME)\ %h%m%r%=%-14.(%l,%c%V%)\ %P
        " Do other customisation here
        setlocal et
        " etc
    endif
endfunc

func! <SID>ConfigureFiletypes(filetype)
    if index(s:GROUPNAMETypes, a:filetype) != -1
        call <SID>CheckForGROUPNAMECode()
    endif
endfunc

Каждый раз, когда открывается файл любого типа и задан тип файла (строка au FileType * ), вызывается функция ConfigureFiletypes . Это проверяет, находится ли тип файла в списке типов файлов, связанных с текущей группой (GROUPNAME), в данном случае 'c', 'cpp', 'vhdl' или 'c.doxygen'. Если это так, он вызывает CheckForGROUPNAMECode (), который читает первые 10 строк файла и, если они содержат GROUPNAME, выполняет некоторые настройки. Помимо установки расширенных вкладок или чего-то еще, это также изменяет строку состояния, чтобы четко отображать имя группы, чтобы вы его знали ' s работает с первого взгляда.

Проверка конфигурации при открытии

Как и в случае с предложением JS Bangs, наличие собственного файла конфигурации может быть полезным. Однако вместо загрузки его в vimrc рассмотрите что-то вроде этого, которое будет проверять, когда файл .c открывается для .vim.custom в том же каталоге, что и файл .c.

au BufNewFile,BufRead *.c call CheckForCustomConfiguration()

function! CheckForCustomConfiguration()
    " Check for .vim.custom in the directory containing the newly opened file
    let custom_config_file = expand('%:p:h') . '/.vim.custom'
    if filereadable(custom_config_file)
        exe 'source' custom_config_file
    endif
endfunction