Выполнение “Группы” запросом в XPath XSL
Учитывая следующий XML:
<results name="queryResults">
<int name="intfield1:[* TO 10]">11</int>
<int name="intfield2:[10 TO 20]">9</int>
<int name="intfield1:[10 TO 20]">12</int>
</results>
Я хотел бы произвести этот XML:
<results>
<field name="numberfield1">
<value name="[* TO 10]">11</value>
<value name="[10 TO 10]">12</value>
</field>
<field name="numberfield2">
<value name="[10 TO 20]">9</value>
</field>
</results>
Я не могу думать, как сделать это в XSL главным образом, потому что я желаю Группе numbericfield.. Все, что я могу придумать, является этим:
<xsl:if test="count(results/int) > 0">
<results>
<xsl:for-each select="results/int">
<field>
<xsl:attribute name="name">
<xsl:value-of select="substring-before(@name, ':')"/></xsl:attribute>
<value>
<xsl:attribute name="name">
<xsl:value-of select="substring-after(@name, ':') "/>
</xsl:attribute>
<xsl:value-of select="."/>
</value>
</field>
</xsl:for-each>
</results>
</xsl:if>
Однако это не производит хороший сгруппированный список вместо этого, я получаю это:
<results>
<field name="numberfield1">
<value name="[* TO 10]">11</value>
</field>
<field name="numberfield2">
<value name="[10 TO 20]">9</value>
</field>
<field name="numberfield1">
<value name="[10 TO 10]">12</value>
</field>
</results>
Если кто-то может регулировать меня в правильном направлении.. Это было бы большим?
Спасибо
2 ответа
Чтобы сделать это в XSLT 1.0, вам нужно будет использовать метод, называемый «мюнхианской группировкой» . Сначала создайте ключ узлов, по которым вы хотите сгруппировать
<xsl:key name="intfield" match="int" use="substring-before(@name, ':')" />
Затем вы перебираете его по всем узлам, но выбираете только те, которые оказались первыми в соответствующей группе
<xsl:for-each select="int[generate-id() = generate-id(key('intfield', substring-before(@name, ':'))[1])]">
Затем вы можете выполнить итерацию, используя ключ для перебора всех узлов в группе
<xsl:variable name="intfieldname" select="substring-before(@name, ':')"/>
<xsl:for-each select="key('intfield', $intfieldname)">
Собирая все вместе, получаем
<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform" version="1.0">
<xsl:output method="xml"/>
<xsl:key name="intfield" match="int" use="substring-before(@name, ':')"/>
<xsl:template match="/results">
<results>
<xsl:for-each select="int[generate-id() = generate-id(key('intfield', substring-before(@name, ':'))[1])]">
<xsl:variable name="intfieldname" select="substring-before(@name, ':')"/>
<field>
<xsl:attribute name="name">
<xsl:value-of select="$intfieldname"/>
</xsl:attribute>
<xsl:for-each select="key('intfield', $intfieldname)">
<value>
<xsl:attribute name="name">
<xsl:value-of select="substring-after(@name, ':')"/>
</xsl:attribute>
<xsl:value-of select="."/>
</value>
</xsl:for-each>
</field>
</xsl:for-each>
</results>
</xsl:template>
</xsl:stylesheet>
В вашем примере, однако, «intfield» становится «numberfield». В приведенном выше примере я сохранил имя как 'intfield'.
- исправлена опечатка.
Мюнчианская группировка - гениальное произведение. Это непросто понять, но посмотрите: http://www.jenitennison.com/xslt/grouping/muenchian.html
Чтобы упростить процесс, W3C специально поддерживал группировку в XSLT2.0. См. Например: http://www.xml.com/pub/a/2003/11/05/tr.html
Однако не все среды поддерживают XSLT2.0