Как я могу перенаправить или передать вывод по каналу исключая командой в мой текущий буфер или файл?
Например, я хочу считать содержание всех регистров в текущий буфер, с помощью который в исключая режимом показывают :registers
.
:redir >name_of_registers_file
:registers
:redir END
:r name_of_registers_file
:help redir
Последняя команда очень полезна, так как есть множество вариантов перенаправления: к переменным, в регистры, как добавить, еще больше рога изобилия.
Мне все еще кажется странным и раздражающим то, что он использует END таким образом, но поскольку все остальное, что может следовать за redir
, должно начинаться с символа, отличного от слова, по крайней мере, это не двусмысленно.
PS AFAIK (что в данном случае довольно далеко), нет возможности прочитать его прямо в буфер: вы должны сначала сохранить его в регистре или переменной. Обратитесь к справке, чтобы узнать, как это сделать.
PPS Если вы все же хотите сделать это с помощью переменной - возможно, чтобы инкапсулировать ее в функцию и избежать засорения регистров или глобальных переменных - вам придется преобразовать многострочную строку, которая записывается в переменную, в список. EG
:call append( '.', split(variable_you_redirected_to, "\n") )
В противном случае (если вы просто выполните append ('.', Var)
) вы получите ^ @ (нули) вместо символов новой строки, поскольку это то, что vimscript использует для представления новой строки в String переменные.
edit : как упоминает @Bill Odom, использование : put = variable_you_redirected_to
намного проще, чем сложное выражение append ()
. Спасибо, Билл!
Я написал сниппет , чтобы сделать этот материал более удобным. Он объявляет функцию Redir (команда, цель)
и команду R
.
Команда анализирует последнюю серию непробельных символов как цель перенаправления и передает ее функции, которая выполняет шаблон для перенаправления вывода команды на цель перенаправления.
Команда - это все, что находится после R
и до последнего пробела.
EG
" Store the vim buffer list in buffer_list.txt
:R ls >buffer_list.txt
" Store error messages emitted by a function being debugged
" in the 'unnamed register'
:R call FunctionBeingDebugged() @">
Здесь есть несколько ограничений: например, вы не сможете писать в имя файла, содержащее пробел. Плюс в том, что вам не нужно цитировать вашу команду. Я разместил его на gist.github.com, и я постараюсь постоянно обновлять его, если в конечном итоге я его улучшу. Или можете сами его форкнуть !
В любом случае фрагмент доступен здесь . Его можно перетащить в файл .vimrc или в файл в ~ /.vim / plugins.
@intuited правильно; команда redir
- это то, что вам нужно. Такой однострочник вставит вывод: registers
в текущий буфер:
redir => m | silent registers | redir END | put=m
Это не то, что вам нужно вводить очень часто, и это не совсем поддается ключевой карте . Я обнаружил, что делаю это довольно часто, поэтому написал функцию и несколько команд, чтобы упростить задачу. В качестве бонуса теперь я могу отправлять выходные данные команды в новое окно или новую вкладку так же легко, как и вставляя их в текущий буфер. Вот код (с несколькими примерами команд в самом конце):
" redir_messages.vim
"
" Inspired by the TabMessage function/command combo found
" at <http://www.jukie.net/~bart/conf/vimrc>.
"
function! RedirMessages(msgcmd, destcmd)
"
" Captures the output generated by executing a:msgcmd, then places this
" output in the current buffer.
"
" If the a:destcmd parameter is not empty, a:destcmd is executed
" before the output is put into the buffer. This can be used to open a
" new window, new tab, etc., before :put'ing the output into the
" destination buffer.
"
" Examples:
"
" " Insert the output of :registers into the current buffer.
" call RedirMessages('registers', '')
"
" " Output :registers into the buffer of a new window.
" call RedirMessages('registers', 'new')
"
" " Output :registers into a new vertically-split window.
" call RedirMessages('registers', 'vnew')
"
" " Output :registers to a new tab.
" call RedirMessages('registers', 'tabnew')
"
" Commands for common cases are defined immediately after the
" function; see below.
"
" Redirect messages to a variable.
"
redir => message
" Execute the specified Ex command, capturing any messages
" that it generates into the message variable.
"
silent execute a:msgcmd
" Turn off redirection.
"
redir END
" If a destination-generating command was specified, execute it to
" open the destination. (This is usually something like :tabnew or
" :new, but can be any Ex command.)
"
" If no command is provided, output will be placed in the current
" buffer.
"
if strlen(a:destcmd) " destcmd is not an empty string
silent execute a:destcmd
endif
" Place the messages in the destination buffer.
"
silent put=message
endfunction
" Create commands to make RedirMessages() easier to use interactively.
" Here are some examples of their use:
"
" :BufMessage registers
" :WinMessage ls
" :TabMessage echo "Key mappings for Control+A:" | map <C-A>
"
command! -nargs=+ -complete=command BufMessage call RedirMessages(<q-args>, '' )
command! -nargs=+ -complete=command WinMessage call RedirMessages(<q-args>, 'new' )
command! -nargs=+ -complete=command TabMessage call RedirMessages(<q-args>, 'tabnew' )
" end redir_messages.vim