Что делает: команда компилятора делает в Vim?

Он устанавливает параметры для этого компилятора, такие как программа, которая будет использоваться для : make , и формат сообщений об ошибках, чтобы vim мог переходить к местам возникновения ошибок. Поищите в $ VIMRUNTIME / compiler / различные файлы .vim, которые можно получить.

: help write-compiler-plugin

Подключаемый модуль компилятора устанавливает параметры для использования с конкретным компилятором. Пользователь может загрузите его командой : compiler . Основное использование - установка Параметры errorformat и makeprg.

См. Также : help errorformat и : help makeprg .

Вот файл компилятора GCC на моем компьютере, например:

/usr/share/vim/vim72/compiler/gcc.vim

" Vim compiler file
" Compiler:         GNU C Compiler
" Maintainer:       Nikolai Weibull <now@bitwi.se>
" Latest Revision:  2006-12-20

if exists("current_compiler")
  finish
endif
let current_compiler = "gcc"

let s:cpo_save = &cpo
set cpo-=C

CompilerSet errorformat=
      \%*[^\"]\"%f\"%*\\D%l:\ %m,
      \\"%f\"%*\\D%l:\ %m,
      \%-G%f:%l:\ %trror:\ (Each\ undeclared\ identifier\ is\ reported\ only\ once,
      \%-G%f:%l:\ %trror:\ for\ each\ function\ it\ appears\ in.),
      \%f:%l:\ %m,
      \\"%f\"\\,\ line\ %l%*\\D%c%*[^\ ]\ %m,
      \%D%*\\a[%*\\d]:\ Entering\ directory\ `%f',
      \%X%*\\a[%*\\d]:\ Leaving\ directory\ `%f',
      \%D%*\\a:\ Entering\ directory\ `%f',
      \%X%*\\a:\ Leaving\ directory\ `%f',
      \%DMaking\ %*\\a\ in\ %f

if exists('g:compiler_gcc_ignore_unmatched_lines')
  CompilerSet errorformat+=%-G%.%#
endif

let &cpo = s:cpo_save
unlet s:cpo_save