Резюме

• Логические тесты
• Увеличение или уменьшение неопределенного значения
• Добавление к неопределенному значению
• Автовивификация
• Другие мутаторы

Логические тесты

Согласно документации perlsyn ,

Число 0 , строки '0' и '' , пустой список () и undef - все они ложны в логическом контексте. Все остальные значения верны.

Поскольку неопределенное значение ложно, следующая программа

#! /usr/bin/perl

use warnings;

my $var;
print "A\n" if $var;
$var && print "B\n";
$var and print "C\n";
print "D\n" if !$var;
print "E\n" if not $var;
$var or print "F\n";
$var || print "G\n";

выводит с D по G без предупреждений.

Увеличение или уменьшение неопределенного значения

Нет необходимости явно инициализировать скаляр нулем, если ваш код будет увеличивать или уменьшать его хотя бы один раз:

#! /usr/bin/perl

use warnings;

my $i;
++$i while "aaba" =~ /a/g;
print $i, "\n";

Приведенный выше код выводит 3 без предупреждения.

Добавление к неопределенному значению

Подобно неявному нулю, нет необходимости явно инициализировать скаляры для пустой строки, если вы добавите к ней хотя бы один раз:

#! /usr/bin/perl

use warnings;
use strict;

my $str;
for (<*>) {
  $str .= substr $_, 0, 1;
}
print $str, "\n";

Autovivification

Один пример: " автовивификация."Из статьи в Википедии :

Автовивификация - отличительная особенность языка программирования Perl, включающая динамическое создание структур данных. Автовивификация - это автоматическое создание ссылки на переменную при разыменовании неопределенного значения. Другими словами, автовивификация Perl позволяет программисту обращаться к структурированной переменной и произвольным подэлементам этой структурированной переменной без явного предварительного объявления существования переменной и ее полной структуры.

Например:

#! /usr/bin/perl

use warnings;

my %foo;
++$foo{bar}{baz}{quux};

use Data::Dumper;
$Data::Dumper::Indent = 1;
print Dumper \%foo;

Даже если мы не инициализируем явно промежуточные ключи, Perl позаботится о каркасе:

$VAR1 = {
  'bar' => {
    'baz' => {
      'quux' => '1'
    }
  }
};

Без автовивификации код потребовал бы большего количества шаблонов:

my %foo;
$foo{bar} = {};
$foo{bar}{baz} = {};
++$foo{bar}{baz}{quux};  # finally!

Не путайте автовивификацию с неопределенными значениями, которые она может произвести. Например, с

#! /usr/bin/perl

use warnings;

my %foo;
print $foo{bar}{baz}{quux}, "\n";
use Data::Dumper;
$Data::Dumper::Indent = 1;
print Dumper \%foo;

получаем

Use of uninitialized value in print at ./prog.pl line 6.

$VAR1 = {
  'bar' => {
    'baz' => {}
  }
};

Обратите внимание, что промежуточные ключи автоматически оживились.

Другие примеры автовивификации:

• ссылка на массив

   my $ a; 
  push @ $ a => "foo"; 
   

• ссылка на скаляр

   my $ s; 
   ++ $$ s; 
   

• ссылка на хэш

   my $ h; 
   $ h-> {foo} = "bar"; 
   

К сожалению, Perl (пока!) не автовивифицирует следующее:

my $code;
$code->("Do what I need please!");

Другие мутаторы

В ответе на аналогичный вопрос ysth сообщает

Некоторые операторы намеренно опускают предупреждение «неинициализировано» для вашего удобства, потому что они обычно используются в ситуациях, когда значение 0 или «» по умолчанию для левого или единственного операнда имеет смысл.

Это: ++ и - (до или после), + = , - = , .= , | = , ^ = , && = , || = .

Будучи «определенным-или», // = успешно изменяет неопределенное значение без предупреждения.