F# записывают членскую оценку

Question

F# записывают членскую оценку

Почему t.b оценен на каждом вызове? И есть ли какой-либо путь, как заставить его оценить только однажды?

type test =
  { a: float }
  member x.b =
    printfn "oh no"
    x.a * 2.

let t = { a = 1. }
t.b
t.b

12

f# record member

задан Oldrich Svec 20 May 2010 в 11:16

3 ответа

Альтернативная версия ответа Брайана, которая оценит b максимум один раз, но не оценит его вообще, если B никогда не используется

type Test(a:float) =
    // constructor
    let b = lazy
                 printfn "oh no"
                 a * 2.
    // properties
    member this.A = a
    member this.B = b.Value

15

ответ дан 2 December 2019 в 04:25

В ответ на ваш комментарий в сообщении Брайана, вы можете подделать выражения копирования и обновления записей, используя необязательные/именованные args. Например:

type Person(?person:Person, ?name, ?age) =

    let getExplicitOrCopiedArg arg argName copy =
        match arg, person with
        | Some(value), _ -> value
        | None, Some(p) -> copy(p)
        | None, None -> nullArg argName

    let name = getExplicitOrCopiedArg name "name" (fun p -> p.Name)
    let age = getExplicitOrCopiedArg age "age" (fun p -> p.Age)

    member x.Name = name
    member x.Age = age

let bill = new Person(name = "Bill", age = 20)
let olderBill = new Person(bill, age = 25)

printfn "Name: %s, Age: %d" bill.Name bill.Age
printfn "Name: %s, Age: %d" olderBill.Name olderBill.Age

4

ответ дан 2 December 2019 в 04:25

Другие вопросы по тегам:

f# record member

Похожие вопросы:

score 13 · Accepted Answer

Это собственность; Вы в основном называете участника get_b().

Если вы хотите, чтобы эффект произошел один раз с конструктором, вы можете использовать класс:

type Test(a:float) =
    // constructor
    let b =   // compute it once, store it in a field in the class
        printfn "oh no"
        a * 2.
    // properties
    member this.A = a
    member this.B = b