Обратимые числовые вычисления в Прологе

is / 2 очень низкоуровневый и ограниченный. Как вы правильно заметили, он не может использоваться во всех направлениях и, следовательно, не является истинным соотношением.

Для обратимой арифметики используйте решатели ограничений системы Prolog .

Например, руководство SWI-Prolog CLP (FD) содержит следующее определение n_factorial / 2 :

:- use_module(library(clpfd)).

n_factorial(0, 1).
n_factorial(N, F) :- N #> 0, N1 #= N - 1, F #= N * F1, n_factorial(N1, F1).

Следующие примеры запросов показывают, что его можно использовать во всех direction:

?- n_factorial(47, F).
F = 258623241511168180642964355153611979969197632389120000000000 ;
false.

?- n_factorial(N, 1).
N = 0 ;
N = 1 ;
false.

?- n_factorial(N, 3).
false.

Конечно, это определение все еще основывается на унификации, и поэтому вы не можете вставлять произвольные целочисленные выражения. Такой термин, как 2-2 (который равен - (2,2) в префиксной записи), не противоречит 0 . Но вы можете легко разрешить это, если переписываете это в:

:- use_module(library(clpfd)).

n_factorial(N, F) :- N #= 0, F #= 1.
n_factorial(N, F) :- N #> 0, N1 #= N - 1, F #= N * F1, n_factorial(N1, F1).

Пример запроса и его результат:

?- n_factorial(2-2, -4+5).
true .

Есть некоторые вещи, которые вы должны помнить при изучении Prolog:

• Не существует неявного возвращаемого значения, когда вы вызываете предикат. Если вы хотите получить значение из вызова, вам нужно добавить дополнительные аргументы, которые могут быть использованы для "возврата" значения, второй аргумент в вашем f/2 предикате. Хотя этот предикат более многословен, он имеет то преимущество, что легко возвращает много значений.

• Это означает, что автоматическая "оценка" аргументов в вызове на самом деле совершенно бессмысленна, поскольку нет значения для возврата, и она не выполняется. Поэтому нет вложенных вызовов, в этом отношении Пролог плоский. Поэтому, когда вы вызываете f(A-1, D), первым аргументом f/2 является структура A-1, или на самом деле -(A, 1), поскольку - является инфиксным оператором. Поэтому, если вы хотите получить значение из вызова foo в вызов bar, вы должны явно использовать переменную для этого, например:

  foo(..., X), bar(X, ...),

• Поэтому вам нужен специальный предикат, который заставляет арифметическую оценку, is/2. Его второй аргумент - это структура, представляющая арифметическое выражение, которое он интерпретирует, оценивает и объединяет результат с первым аргументом, который может быть либо переменной, либо числовым значением.

• Хотя в принципе вы можете выполнять обратные действия с большинством вещей, это не так. Обычно это возможно только для простых предикатов, работающих со структурами, хотя есть несколько очень полезных случаев, когда это возможно. is/2 не работает в обратном направлении, это было бы исключительным случаем, если бы работало.

Вот почему вам нужны дополнительные переменные C и D и вы не можете заменить C is A-1, f(C, D) на f(A-1,D).

(Да, я знаю, что в Прологе нельзя делать вызовы, а можно оценивать цели, но мы исходили из функциональной точки зрения)