Как этот код Perl выбирает два различных элемента из массива?

Это похоже на некоторый код C с синтаксисом Perl. Иногда знание языка, на котором думает человек, помогает понять, что происходит. В этом случае мозг человека заражен внутренними механизмами управления памятью, арифметикой указателей и другими низкоуровневыми проблемами, поэтому он хочет постоянно контролировать все:

my @selected_heads = ();

# a tricky way to make a two element array
for my $i (0..1) {

   # choose a random file
   $selected_heads[$i] = int rand @heads;

   # for all the files (could use $#heads instead)
   for my $j (0..@heads-1) {
      # stop if the chosen file is not already in @selected_heads
      # it's that damned ! in front of the grep that's mind-warping
      last if (!grep $j eq $_, @selected_heads[0..$i-1]);

      # if we are this far, the two files we selected are the same
      # choose a different file if we're this far
      $selected_heads[$i] = ($selected_heads[$i] + 1) % @heads; #WTF?
   }

...
}

Это большая работа, потому что исходный программист либо не делает этого » не понимает хешей или не любит их.

my %selected_heads;
until( keys %selected_heads == 2 )
    {
    my $try = int rand @heads;
    redo if exists $selected_heads{$try};
    $selected_heads{$try}++;
    }

my @selected_heads = keys %selected_heads;

Если вы все еще ненавидите хеши и у вас есть Perl 5.10 или новее, вы можете использовать интеллектуальное сопоставление, чтобы проверить, находится ли значение в массиве:

my @selected_heads;
until( @selected_heads == 2 )
    {
    my $try = int rand @heads;
    redo if $try ~~ @selected_heads;
    push @selected_heads, $try;
    }

Однако у вас есть особые ограничения для этой проблемы. Поскольку вы знаете, что есть только два элемента, вам просто нужно проверить, является ли элемент, который вы хотите добавить, предыдущим. В первом случае это не будет undef, поэтому первое добавление всегда работает. Во втором случае это просто не может быть последним элементом в массиве:

my @selected_heads;
until( @selected_heads == 2 )
    {
    my $try = int rand @heads;
    redo if $try eq $selected_heads[-1];
    push @selected_heads, $try;
    }

Ха. Я не могу вспомнить, когда я последний раз использовал , до , когда это действительно соответствовало задаче. :)

Обратите внимание, что у всех этих решений есть проблема, заключающаяся в том, что они могут вызвать бесконечный цикл, если количество исходных файлов меньше 2. Я бы добавил условие защиты выше, так что случаи отсутствия и одного файла через ошибка и, возможно, дело с двумя файлами не потрудится их упорядочить.

Другой способ сделать это - перетасовать (скажем, с помощью List :: Util ) весь список исходных файлов и просто удалить первые два файла:

use List::Util qw(shuffle);

my @input = 'a' .. 'z';

my @two = ( shuffle( @input ) )[0,1];

print "selected: @two\n";