Как я сохраняю сокеты в хеше и цикле по ним от другого потока?

Question

Как я сохраняю сокеты в хеше и цикле по ним от другого потока?

Я работаю над mulithreaded сервером TCP. В основном потоке я слушаю на сокете и создаю новый поток для новых входящих соединений. Я хочу сохранить все входящие соединения в хеше так, чтобы я мог получить доступ к ним от еще одного потока.

От потока монитора я не могу считать недавно добавленные соединения. Кажется, что новый клиентский хеш создается при создании потока монитора.

Как я сохраняю список всех сокетов и циклично выполняю их от моего потока монитора?

Текущий код:

#!/usr/bin/perl
use strict;
use IO::Socket;
use threads;
use Thread::Queue;

# init
my $clients = {};
my $queue = Thread::Queue->new;

# thread that monitors
threads->create("monitor");

# create the listen socket
my $listenSocket = IO::Socket::INET->new(LocalPort  => 12345,
                                      Listen   => 10,
                                      Proto   => 'tcp',
                                      Reuse   => 1);

# make sure we are bound to the port
die "Cant't create a listening socket: $@" unless $listenSocket;

print "Server ready. Waiting for connections on 34567 ... \n";

# wait for connections at the accept call
while (my $connection = $listenSocket->accept) {
    # set client socket to non blocking
    my $nonblocking = 1;
    ioctl($connection, 0x8004667e, \\$nonblocking);

    # autoflush
    $connection->autoflush(1);

    # debug
    print "Accepted new connection\n";

    # add to list
    $clients->{time()} = $connection;

    # start new thread and listen on the socket
    threads->create("readData", $connection);
}

sub readData {
     # socket parameter
     my ($client) = @_;

     # read client
     while (<$client>) {
      # remove newline
      chomp $_;

  # add to queue
      $queue->enqueue($_);
     }

     close $client;
}

sub monitor {
    # endless loop
    while (1) {

        # loop while there is something in the queue
        while ($queue->pending) {

            # get data from a queue
            my $data = $queue->dequeue;

            # loop all sockets
            while ( my ($key, $value) = each(%$clients) ) {

               # send to socket
               print $value "$data\n";

            }
        }

        # wait 0,25 seconds
        select(undef, undef, undef, 0.25);
    }
}

close $listenSocket;

8

perl sockets multithreading

задан Greg Bacon 28 December 2013 в 17:25

2 ответа

У меня нет большого опыта использования потоков в Perl, но я думаю, вы просто хотите поделиться своим списком клиентов:

    use threads::shared;
    my $clients : shared = {};

Обновление:

Perl жалуется на:

my $hash : shared = {};

, но вроде как:

my $hash = {};
share($hash);

Кроме того, этот код:

my $hash = { key1 => "value1" };
share($hash);

, кажется, очищает хеш-таблицу, но

my $hash = {};
share($hash);
$hash->{key1} = "value1";

работает так, как я ожидал.

1

ответ дан 5 December 2019 в 18:59

Другие вопросы по тегам:

perl sockets multithreading

Похожие вопросы:

score 8 · Accepted Answer

Вам необходимо предоставить доступ к $ клиентам через share из thread :: shared :

my $clients = &share({});

Старомодный синтаксис возник из-за задокументированной проблемы с прототипами Perl. Если у вас хотя бы Perl 5.8.9 , используйте вместо него более приятный

my $clients = shared_clone({});

.

Вы также хотите защитить $ клиентов блокировкой, например. ,

my $clients_lock : shared;
{
  lock $clients_lock;
  $clients->{time()} = fileno $connection;
}

Наконец, поскольку экземпляры IO :: Socket :: INET являются типами Perl, вы не можете совместно использовать их, поэтому вместо этого добавьте их дескрипторы сокетов (из fileno ) к $ client , а затем fdopen сокет, когда это необходимо с

open my $fh, ">&=", $sockdesc or warn ...

. Программа ниже повторяет входящие данные в другие подключенные сокеты:

#!/usr/bin/perl

use strict;
use IO::Socket;
use threads;
use threads::shared;
use Thread::Queue;

# init
my $clients = &share({});
my $clients_lock : shared;

my $queue = Thread::Queue->new;

# thread that monitors
threads->create("monitor");

# create the listen socket
my $port = 12345;
my $listenSocket = IO::Socket::INET->new(
  LocalPort  => $port,
  Listen     => 10,
  Proto      => 'tcp',
  Reuse      => 1
);

# make sure we are bound to the port
die "Can't create a listening socket: $@" unless $listenSocket;

print "Server ready. Waiting for connections on $port ... \n";

# wait for connections at the accept call
while (my $connection = $listenSocket->accept) {
  # set client socket to non blocking
  my $nonblocking = 1;
  ioctl($connection, 0x8004667e, \\$nonblocking);

  # autoflush
  $connection->autoflush(1);

  # debug
  print "Accepted new connection\n";

  # add to list
  {
    lock $clients_lock;
    $clients->{time()} = fileno $connection;
  }

  # start new thread and listen on the socket
  threads->create("readData", $connection);
}

sub readData {
  # socket parameter
  my ($client) = @_;

  # read client
  while (<$client>) {
    chomp;
    $queue->enqueue($_);
  }

  close $client;
}

sub monitor {
  # endless loop
  while (1) {
    # loop while there is something in the queue
    while ($queue->pending) {
      # get data from a queue
      my $data = $queue->dequeue;

      # loop all sockets
      {
        lock $clients_lock;
        while ( my ($key, $value) = each(%$clients) ) {
          # send to socket
          if (open my $fh, ">&=", $value) {
            print $fh "$data\n";
          }
          else {
            warn "$0: fdopen $value: $!";
          }
        }
      }
    }

    # wait 0,25 seconds
    select(undef, undef, undef, 0.25);
  }
}

close $listenSocket;