Получите значение ключа реестра

Question

Получите значение ключа реестра

У меня есть сценарий пакетной обработки, который проверяет, существует ли ключ реестра и если он действительно существует затем открытый Internet Explorer. То, что я теперь хочу сделать, получают значение того ключа реестра и помещают его в URL. Как я могу сделать это?

@echo off
reg query HKLM\Software\Test\Monitor\Settings
if errorlevel 1 goto not_exist
goto exist

:not_exist

:exist
start "Test" "%ProgramFiles%\Internet Explorer\iexplore.exe" http://localhost:/dashboard.php

Спасибо все для любой справки.

7

batch-file dos command-prompt

задан Abs 9 July 2010 в 14:29

1 ответ

Другие вопросы по тегам:

batch-file dos command-prompt

Похожие вопросы:

score 19 · Accepted Answer

Вот так, все должно быть понятно с комментариями. Дайте мне знать, если у вас возникнут вопросы.

@echo off

set THEME_REGKEY=HKLM\Software\Microsoft\Windows\CurrentVersion\Themes
set THEME_REGVAL=ThemeName

REM Check for presence of key first.
reg query %THEME_REGKEY% /v %THEME_REGVAL% 2>nul || (echo No theme name present! & exit /b 1)

REM query the value. pipe it through findstr in order to find the matching line that has the value. only grab token 3 and the remainder of the line. %%b is what we are interested in here.
set THEME_NAME=
for /f "tokens=2,*" %%a in ('reg query %THEME_REGKEY% /v %THEME_REGVAL% ^| findstr %THEME_REGVAL%') do (
    set THEME_NAME=%%b
)

REM Possibly no value set
if not defined THEME_NAME (echo No theme name present! & exit /b 1)

REM replace any spaces with +
set THEME_NAME=%THEME_NAME: =+%

REM open up the default browser, searching google for the theme name
start http://www.google.com/search?q=%THEME_NAME%