Параллель Perl:: ForkManager с обработчиками баз данных DBI

Question

Параллель Perl:: ForkManager с обработчиками баз данных DBI

Я интересуюсь выполнением нескольких действий базы данных параллельно. Я играл с Параллелью Perl:: ForkManager, но не используемый это с любыми базами данных все же. Я читал, та возможность соединения базы данных не поддерживается очень хорошо с этим. У кого-либо есть опыт с этим?

Как пример я, вероятно, породил бы системный вызов (который делает работу DBI), НЕ необработанный код, т.е.

#!/opt/local/bin/perl -w

use strict;
use Parallel::ForkManager;

$| = 1;

my $max_procs = 10;

my $pm =  new Parallel::ForkManager($max_procs);

for (my $var = 0; $var <= 10; $var++) {
  my $pid = $pm->start('proc'.$var) and next;
  sleep ( 2 );
  system( "./DBworker.pl $var" );
  $pm->finish(0); 
}

print "Waiting for child procs\n";
$pm->wait_all_children;
print "complete!\n";

6

perl dbi parallel-processing

задан nick fox 27 June 2010 в 11:40

1 ответ

Другие вопросы по тегам:

perl dbi parallel-processing

Похожие вопросы:

score 9 · Accepted Answer

Если работа выполняется другими программами, нет никакой опасности для forking. Опасность возникает, когда вы открываете соединение с базой данных, а затем делаете развилку. Ребенок не может повторно использовать родительское соединение; однако, взгляните на DBIx::Connector, он обрабатывает вещи, которые вам нужно сделать после forking за вас, и запуск нескольких программ, как правило, не является правильным решением.

#!/usr/bin/perl

use strict;
use warnings;

use DBIx::Connector;
use Parallel::ForkManager;

my $dsn  = "dbi:SQLite:dbname=foo.db";
my $user = "";
my $pass = "";
my $conn = DBIx::Connector->new($dsn, $user, $pass, 
    {
        AutoCommit       => 0,
        PrintError       => 0,
        RaiseError       => 1,
        ChopBlanks       => 1,
        FetchHashKeyName => 'NAME_lc',
    }
);
END { unlink "foo.db" }

#setup table
$conn->run(fixup => sub {
    my $dbh = $_;
    $dbh->do("create table foo ( id integer, name char(35) )");
    my $sth = $dbh->prepare("insert into foo (id, name) values (?, ?)");
    while (<DATA>) {
        chomp;
        $sth->execute(split /,/);
    }
});

my $pm = Parallel::ForkManager->new(3);

my $sth = $conn->dbh->prepare("select * from foo where id = ?");
for my $id (1 .. 3) {
    next if $pm->start;
    $sth->execute($id);
    while (my $row = $sth->fetchrow_hashref) {
        print "$id saw $row->{id} => $row->{name}\n";
    }
    $pm->finish;
}

$pm->wait_all_children;

print "done\n";

__DATA__
1,foo
2,bar
3,baz