Вопросы Теги

Perl, эквивалентный из 'отклонения Ruby!'?

Я нуждаюсь к технической победе в массиве и условно удаляю элементы в Perl. Я знаю о slice, но не уверено, как использовать его в a foreach контекст.

В Ruby, существует reject!:

foo = [2, 3, 6, 7]
foo.reject! { |x| x > 3 }
p foo   # outputs "[2, 3]"

Существует ли эквивалентный Perl?

5
задан Stéphan Kochen 15 July 2010 в 08:56
поделиться

3 ответа

@foo = (2, 3, 6, 7);
@foo = grep { $_ <= 3 } @foo;
print @foo; # 23
22
ответ дан 18 December 2019 в 05:30
поделиться

Как показывают другие ответы, grep , как правило, все, что вам нужно.

Однако с помощью прототипов Perl можно закодировать функцию, которая, как Array # reject! :

  • принимает блок
  • может изменять свой массив аргументов на месте

Использование: 

@foo = (2, 3, 6, 7);            # Void context - modify @foo in place
reject { $_ > 3 } @foo;         # @foo is now (2, 3)

@foo = (2, 3, 6, 7);            # Scalar context - modify @foo in place
$n = reject { $_ > 3 } @foo;    # @foo is now (2, 3), $n is length of modified @foo

@foo = (2, 3, 6, 7);            # Array context - return a modified copy of @foo
@cpy = reject { $_ > 3 } @foo;  # @cpy is (2, 3), @foo is (2, 3, 6, 7)

Реализация: 

sub reject(&\@) {
    my ($block, $ary) = @_;

    # Return a copy in an array context
    return grep {! $block->() } @$ary if wantarray;

    # Otherwise modify in place.  Similar to, but not
    # quite, how rb_ary_reject_bang() does it.
    my $i = 0;
    for (@$ary) {
            next if $block->();
            ($ary->[$i], $_) = ($_, $ary->[$i]); # swap idiom to avoid copying
            $i++;                                # possibly huge scalar
    }
    $#$ary = $i - 1;  # Shorten the input array

    # We differ from Array#reject! in that we return the number of
    # elements in the modified array, rather than an undef value if
    # no rejections were made
    return scalar(@$ary) if defined(wantarray);
}
8
ответ дан 18 December 2019 в 05:30
поделиться 
vinko@parrot:/home/vinko# more reject.pl
my @numbers = (2, 3, 6 ,7);
print join(",", grep { $_ <= 3 } @numbers)."\n";

vinko@parrot:/home/vinko# perl reject.pl
2,3
4
ответ дан 18 December 2019 в 05:30
поделиться