Почему не делает Попытки Perl:: попытка/выгода Tiny дает мне те же результаты как оценку?

Question

Почему не делает Попытки Perl:: попытка/выгода Tiny дает мне те же результаты как оценку?

Почему не делает подпрограммы с попыткой/выгодой, дают мне те же результаты, как версия оценки делает?

#!/usr/bin/env perl
use warnings; use strict;
use 5.012;
use Try::Tiny;

sub shell_command_1 {
    my $command = shift;
    my $timeout_alarm = shift;
    my @array;
    eval {
        local $SIG{ALRM} = sub { die "timeout '$command'\n" };
        alarm $timeout_alarm;
        @array = qx( $command );
        alarm 0;
    };
    die $@ if $@ && $@ ne "timeout '$command'\n";
    warn $@ if $@ && $@ eq "timeout '$command'\n";
    return @array;
}
shell_command_1( 'sleep 4', 3 );
say "Test_1";

sub shell_command_2 {
    my $command = shift;
    my $timeout_alarm = shift;
    my @array;
    try {
        local $SIG{ALRM} = sub { die "timeout '$command'\n" };
        alarm $timeout_alarm;
        @array = qx( $command );
        alarm 0;
    }
    catch {
    die $_ if $_ ne "timeout '$command'\n";
    warn $_ if $_ eq "timeout '$command'\n";
    }
    return @array;
}
shell_command_2( 'sleep 4', 3 );
say "Test_2"

5

perl eval try-catch

задан brian d foy 21 May 2010 в 00:34

1 ответ

Другие вопросы по тегам:

perl eval try-catch

Похожие вопросы:

score 12 · Accepted Answer

Вам не хватает последней точки с запятой в блоках try/catch.

У вас есть:

try  {
    ...
}
catch {
    ...
}
return;

Итак, у вас есть код, который эквивалентен: try( CODEREF, catch( CODEREF, return ) );

Обновление:

Я забыл упомянуть, чтобы исправить ваш код, просто измените shell_command_2:

sub shell_command_2 {
    my $command = shift;
    my $timeout_alarm = shift;
    my @array;
    try {
        local $SIG{ALRM} = sub { die "timeout '$command'\n" };
        alarm $timeout_alarm;
        @array = qx( $command );
        alarm 0;
    }
    catch {
        die $_ if $_ ne "timeout '$command'\n";
        warn $_ if $_ eq "timeout '$command'\n";
    };           # <----- Added ; here <======= <======= <======= <=======
    return @array;
}