Как добавить заголовок, нижний колонтитул с изображениями с помощью PDF:: API2:: Облегченный?

Question

Как добавить заголовок, нижний колонтитул с изображениями с помощью PDF:: API2:: Облегченный?

Действительно ли возможно добавить заголовок (с текстом и одним изображением) и нижний колонтитул (с номером страницы) с изображениями. Я записал ниже кода для создания документа в формате PDF, который показывает изображения png.

Если это может быть сделано легко с каким-либо другим модулем, предложите. Действительно цените ответ с примером кода.

use strict;
use PDF::API2::Lite;
use Getopt::Long;

my $outfile;
my $path;

my $options = GetOptions( "outfile=s" => \$outfile,
                          "images=s" => \$path,);

my @images = sort glob("$path") or die "No Files\n";

my $pdf = PDF::API2::Lite->new();
for my $png ( sort @images ) {
        my $image = $pdf->image_png( "$png" );
        $pdf->page(1150,450);
        $pdf->image($image, 10, 10);
}

$pdf->saveas( $outfile );

5

perl pdf perl-module

задан Space 9 June 2010 в 11:00

3 ответа

Другие вопросы по тегам:

perl pdf perl-module

Похожие вопросы:

score 4 · Answer 1

Ожидание одного дня на SO сэкономило вам 10 минут на чтение документации модуля. Это не сложно, Космос.

use PDF::API2 qw();

{
    my $pdf = PDF::API2->open('input.pdf');

    for my $index (1 .. $pdf->pages) {
        my $page = $pdf->openpage($index);
        my $txt  = $page->text;
        $txt->textlabel(300, 700, $pdf->corefont('Helvetica Bold'), 12, 'some Header text');

        my $gfx = $page->gfx;
        $gfx->image($pdf->image_png('Header_image.png'), 150, 700);

        $txt->textlabel(300, 100, $pdf->corefont('Helvetica Bold'), 12, "Page: $index");
    }

    $pdf->saveas('output.pdf');
    $pdf->end;
}

score 1 · Answer 2

Посмотрите на PDF::API2::Simple вместо этого. Этот CPAN-модуль предоставляет несколько удобных вспомогательных методов для PDF::API2 включая заголовки и колонтитулы.

Вот простой рабочий пример заголовка/футера:

use 5.012;
use warnings;
use PDF::API2::Simple;

our $PageNo;

my $pdf = PDF::API2::Simple->new(
    file   => 'file.pdf',
    header => \&header,
    footer => \&footer,
);

$pdf->add_font('Verdana');

for my $page (1..3) {
    $pdf->add_page;
    $pdf->image( 'image.png', x => 300, y => 300 );
}
$pdf->save;  


sub header { shift->text( 'Header text here' ) }
sub footer { shift->text( 'page:  ' . ++$PageNo, x => 10, y => 10 ) }

/I3az/

score 4 · Answer 3

PDF :: API2 - моя рабочая лошадка для такого рода вещей.

И я почти всегда буду использовать метод importPageIntoForm , как только мне понадобится выполнить наложение или повторную обработку существующего документа PDF.

В качестве общего решения я создаю новый PDF-файл, постранично, импортирую элементы, которые хочу разместить, а затем добавляю дополнительный текст или графику.

#!/usr/bin/perl
use warnings; use strict;

use PDF::API2;

my $infile = shift (@ARGV);
my $outfile = shift (@ARGV);

die "usage $0: infile outfile"
unless $infile && $outfile;

my $pdf_in = PDF::API2->open($infile);
my $pdf_out = PDF::API2->new;

foreach my $pagenum (1 .. $pdf_in->pages) {

  my $page_in = $pdf_in->openpage($pagenum);
  #
  # create a new page
  #
  my $page_out = $pdf_out->page(0);

  my @mbox = $page_in->get_mediabox;
  $page_out->mediabox(@mbox);

  my $xo = $pdf_out->importPageIntoForm($pdf_in, $pagenum);

  #
  # lay up the input page in the output page
  # note that you can adjust the position and scale, if required
  #
  my $gfx = $page_out->gfx;

  $gfx->formimage($xo,
          0, 0, # x y
          1);   # scale

  #
  # add page number text
  #
  my $txt = $page_out->text;

  $txt->strokecolor('#000000');

  $txt->translate(
          my $_x = 200,
          my $_y = 50
  );

  my $font = $pdf_out->corefont('Courier');
  $txt->font($font, 12);
  $txt->text( 'Page: '.$pagenum );

  #
  # add header image
  #

  my $header_img = $pdf_out->image_png('SomeHeader.png');
  $gfx->image($header_img, 0, 400);
}

$pdf_out->saveas($outfile);