Фильтрация DBNull с LINQ

Question

Фильтрация DBNull с LINQ

Почему следующее запрашивает, повышают ошибку ниже для строки с a NULL значение для барреля, когда я явно отфильтровываю те строки в Where пункт?

Dim query = From row As dbDataSet.conformalRow In dbDataSet.Tables("conformal") _
            Where Not IsDBNull(row.Cal) AndAlso tiCal_drop.Text = row.Cal _
            AndAlso Not IsDBNull(row.Tran) AndAlso tiTrans_drop.Text = row.Tran _
            AndAlso Not IsDBNull(row.barrel) _
            Select row.barrel
If query.Count() > 0 Then tiBarrel_txt.Text = query(0)

Run-time exception thrown : System.Data.StrongTypingException - The value for column 'barrel' in table 'conformal' is DBNull.

Как должен мой запрос / условие быть переписанным для работы, как я предназначил?

5

vb.net linq null dbnull

задан Steven 8 March 2010 в 16:43

1 ответ

Другие вопросы по тегам:

vb.net linq null dbnull

Похожие вопросы:

score 7 · Accepted Answer

По умолчанию в строго типизированных наборах данных свойства вызывают это исключение, если поле имеет значение NULL. Вам необходимо использовать сгенерированный метод Is [Field] Null :

Dim query = From row As dbDataSet.conformalRow In dbDataSet.Tables("conformal") _
            Where Not row.IsCalNull() AndAlso tiCal_drop.Text = row.Cal _
            AndAlso Not row.IsTranNull() AndAlso tiTrans_drop.Text = row.Tran _
            AndAlso Not row.IsbarrelNull() _
            Select row.barrel
If query.Count() > 0 Then tiBarrel_txt.Text = query(0)

Или метод DataRow.IsNull:

Dim query = From row As dbDataSet.conformalRow In dbDataSet.Tables("conformal") _
            Where Not row.IsNull("Cal") AndAlso tiCal_drop.Text = row.Cal _
            AndAlso Not row.IsNull("Tran") AndAlso tiTrans_drop.Text = row.Tran _
            AndAlso Not row.IsNull("barrel") _
            Select row.barrel
If query.Count() > 0 Then tiBarrel_txt.Text = query(0)