Как сопоставить строку с диакритическим знаком в perl?

Например, сопоставьте «Nation» в «ñţérñåţîöñåļîžåţîöñ» без дополнительных модулей. Возможно ли это в новых версиях Perl (5.14, 5.15 и т.д.)?

Я нашел ответ! Благодаря решению tchrist

Rigth с соответствием UCA (спасибо https://stackoverflow.com/users/471272/tchrist ).

# found start/end offsets for matched utf-substring (without intersections)
use 5.014;
use strict; 
use warnings;
use utf8;
use Unicode::Collate;
binmode STDOUT, ':encoding(UTF-8)';
my $str  = "Îñţérñåţîöñåļîžåţîöñ" x 2;
my $look = "Nation";
my $Collator = Unicode::Collate->new(
    normalization => undef, level => 1
   );

my @match = $Collator->match($str, $look);
if (@match) {
    my $found = $match[0];
    my $f_len  = length($found);
    say "match result: $found (length is $f_len)"; 
    my $offset = 0;
    while ((my $start = index($str, $found, $offset)) != -1) {                                                  
        my $end   = $start + $f_len;
        say sprintf("found at: %s,%s", $start, $end);
        $offset = $end + 1;
    }
}

Неверное (но работающее) решение из http://www.perlmonks.org/?node_id=485681

Волшебный фрагмент кода:

    $str = Unicode::Normalize::NFD($str); $str =~ s/\pM//g;

пример кода:

    use 5.014;
    use utf8;
    use Unicode::Normalize;

    binmode STDOUT, ':encoding(UTF-8)';
    my $str  = "Îñţérñåţîöñåļîžåţîöñ";
    my $look = "Nation";
    say "before: $str\n";
    $str = NFD($str);
    # M is short alias for \p{Mark} (http://perldoc.perl.org/perluniprops.html)
    $str =~ s/\pM//og; # remove "marks"
    say "after: $str";¬
    say "is_match: ", $str =~ /$look/i || 0;