Objective-C - Недостатки моста с C++?

Итак, мне сегодня стало скучно, и я решил возиться с интерполяцией C++/Obj-C, и я нашел способ создать очень интересную настройку.

@protocol NSCPPObj <NSObject>

-(id) init;
-(id) initWithInt:(int) value;
-(int) somethingThatReturnsAValue;
-(void) doSomething;

@end

class NSCPPObj : objc_object {
public:    
    static Class cls();

    int iVar;

    NSCPPObj();
    NSCPPObj(int);

    int somethingThatReturnsAValue();
    void doSomething();
};

Как видите, интерфейс довольно прост и понятен. Мы создаем два (почти) идентичных интерфейса, один для объекта C++, а другой для протокола Obj-C.

Теперь я нашел способ реализовать это, но приготовьтесь, это становится уродливым:

// NSCPPObj.mm
#import <objc/runtime.h>
#import <iostream>

#import "NSCPPObject.h"

Class NSCPPObj_class = nil;

__attribute__((constructor))
static void initialize()
{
    NSCPPObj_class = objc_allocateClassPair([NSObject class], "NSCPPObj", 0);

    class_addMethod(NSCPPObj_class->isa, @selector(alloc), imp_implementationWithBlock(^(id self) {
        return class_createInstance(NSCPPObj_class, sizeof(struct NSCPPObj));
    }), "@@:");

    class_addMethod(NSCPPObj_class, @selector(init), imp_implementationWithBlock(^(id self) {
        return self;        
    }), "@@:");

    class_addMethod(NSCPPObj_class, @selector(initWithInt:), imp_implementationWithBlock(^(id self, int value) {
        ((struct NSCPPObj *) self)->iVar = value;

        return self;
    }), "@@:i");

    class_addMethod(NSCPPObj_class, @selector(doSomething), imp_implementationWithBlock(^(id self) {
        ((struct NSCPPObj *) self)->doSomething();
    }), "v@:");
    class_addMethod(NSCPPObj_class, @selector(somethingThatReturnsAValue), imp_implementationWithBlock(^(id self) {
        return ((struct NSCPPObj *) self)->somethingThatReturnsAValue();
    }), "i@:");

    objc_registerClassPair(NSCPPObj_class);
}

Class NSCPPObj::cls()
{
    return NSCPPObj_class;
}

NSCPPObj::NSCPPObj()
{
    this->isa = NSCPPObj_class;
    [((id<NSCPPObj>) this) init];
}

NSCPPObj::NSCPPObj(int value)
{
    this->isa = NSCPPObj_class;
    [((id<NSCPPObj>) this) initWithInt:value];
}

void NSCPPObj::doSomething()
{
    std::cout << "Value Is: " << [((id<NSCPPObj>) this) somethingThatReturnsAValue] << std::endl;
}

int NSCPPObj::somethingThatReturnsAValue()
{
    return iVar;
}

Я подведу итог тому, что это делает:

1. Выделяет пару классов
2. Добавляет все методы класса и экземпляра к объекту
3. Регистрирует пару классов

Теперь, как вы можете видеть, это не очень гибко, но это работает, и это улица с двусторонним движением:

id<NSCPPObj> obj = [[NSCPPObj::cls() alloc] initWithInt:15];
[obj doSomething];

NSLog(@"%i", [obj somethingThatReturnsAValue]);
NSLog(@"%@", obj);

NSCPPObj *objAsCPP = (__bridge NSCPPObj *) obj;

objAsCPP->doSomething();
std::cout << objAsCPP->somethingThatReturnsAValue() << std::endl;

Вы также можете создать объект с помощью нового NSCPPObj(15), но не забудьте удалить его! Очевидно, что это может работать в среде ARC или без ARC, но ARC требует нескольких дополнительных мостовых отливок.

Итак, я подхожу к реальному вопросу:
Каковы плюсы / минусы этой структуры дизайна? Я могу перечислить несколько из них:

Плюсы:

1. Перегрузка оператора C++
2. Привязка динамических методов с ObjC
3. Может быть построена в стиле C++ или ObjC

Минусы:

1. Трудночитаемая реализация
2. Селекторы и привязки должны быть добавлены для каждой реализации C++, добавленной в интерфейс
3. Объект класса нельзя ссылаться напрямую

Таким образом, После всего этого Вы бы порекомендовали эту структуру проектирования в приложении? и почему.