Android SDK и AVD Manager не запускаются

Я установил Android SDK, но не могу его использовать, потому что AVD и менеджеры SDK не запускаются. их окно командной строки появляется примерно на полсекунды, а затем закрывается.Я попытался запустить exe из командной строки, чтобы увидеть, было ли сообщение об ошибке, но есть нет выхода, и он действует так же. Я исследовал проблему и обнаружил, что то же самое происходит и с другими компьютерами.Я пробовал некоторые из решений, которые были опубликованы там:

Решения, которые, похоже, не работают

• Добавление местоположения JDK в начало переменной среды PATH
• Добавление Android SDK расположение в переменной окружения PATH
• Запуск приложений от имени администратора
• Удаление папки .androidу пользователя ( C:/Users/[Имя пользователя ]) каталог
• Установка в корень диска C:, а не в Program Files

Информация об ОС: Windows 7 Home Premium, права администратора

Обновление

Я думаю, что нашел источник проблемы, но я до сих пор не знаю, как это исправить. Похоже, проблема связана с моим файлом android.batв каталоге C:\Android\android-sdk\tools. Он пытается вызвать find_java.bat, но не может из-за небольшой синтаксической проблемы. Вот вывод:

'C:\Android\ANDROI~1\tools\lib\find_java.exe -s' не распознается как внутренняя или внешняя команда, исполняемая программа или пакетный файл.

ОШИБКА: Подходящая Java не найдена. Чтобы правильно использовать Android Developer Tools вам потребуется подходящая версия Java JDK, установленная в вашей системе. Мы рекомендуем вам установить JDK-версию JavaSE, доступную здесь: http://www.oracle.com/technetwork/java/javase/downloads

Полные требования к Android SDK можно найти здесь: http://developer.android.com/sdk/requirements.html

После некоторых изменений в android.batя смог заставить его вызывать find_java.bat, который, в свою очередь, выдавал кучу ошибок, что бы я с ним ни делал. В конце концов я разочаровался и решил жестко закодировать расположение java.exe. Позже в батнике была еще одна ошибка. Я начинаю думать, что что-то действительно не так с моей установкой или командным файлом. Это пакетный файл ( android.bat):

@echo off
rem Copyright (C) 2007 The Android Open Source Project
rem
rem Licensed under the Apache License, Version 2.0 (the "License");
rem you may not use this file except in compliance with the License.
rem You may obtain a copy of the License at
rem
rem      http://www.apache.org/licenses/LICENSE-2.0
rem
rem Unless required by applicable law or agreed to in writing, software
rem distributed under the License is distributed on an "AS IS" BASIS,
rem WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
rem See the License for the specific language governing permissions and
rem limitations under the License.

rem Useful links:
rem Command-line reference:
rem   http://technet.microsoft.com/en-us/library/bb490890.aspx

rem don't modify the caller's environment
setlocal

rem Set up prog to be the path of this script, including following symlinks,
rem and set up progdir to be the fully-qualified pathname of its directory.
set prog=%~f0

rem Grab current directory before we change it
set work_dir="%cd%"

rem Change current directory and drive to where the script is, to avoid
rem issues with directories containing whitespaces.
cd /d %~dp0


rem Check we have a valid Java.exe in the path.
set java_exe=
call lib\find_java.bat
if not defined java_exe goto :EOF

set jar_path=lib\sdkmanager.jar;lib\swtmenubar.jar

rem Set SWT.Jar path based on current architecture (x86 or x86_64)
for /f %%a in ('%java_exe% -jar lib\archquery.jar') do set swt_path=lib\%%a

:MkTempCopy
    rem Copy android.bat and its required libs to a temp dir.
    rem This avoids locking the tool dir in case the user is trying to update it.

    set tmp_dir=%TEMP%\temp-android-tool
    xcopy %swt_path% %tmp_dir%\%swt_path% /I /E /C /G /R /Y /Q > nul
    copy /B /D /Y lib\androidprefs.jar   %tmp_dir%\lib\        > nul
    copy /B /D /Y lib\org.eclipse.*      %tmp_dir%\lib\        > nul
    copy /B /D /Y lib\sdk*               %tmp_dir%\lib\        > nul
    copy /B /D /Y lib\common.jar         %tmp_dir%\lib\        > nul
    copy /B /D /Y lib\commons-compress*  %tmp_dir%\lib\        > nul
    copy /B /D /Y lib\swtmenubar.jar     %tmp_dir%\lib\        > nul
    copy /B /D /Y lib\commons-logging*   %tmp_dir%\lib\        > nul
    copy /B /D /Y lib\commons-codec*     %tmp_dir%\lib\        > nul
    copy /B /D /Y lib\httpclient*        %tmp_dir%\lib\        > nul
    copy /B /D /Y lib\httpcore*          %tmp_dir%\lib\        > nul
    copy /B /D /Y lib\httpmime*          %tmp_dir%\lib\        > nul

    rem jar_path and swt_path are relative to PWD so we don't need to adjust them, just change dirs.
    set tools_dir=%cd%
    cd /d %tmp_dir%

:EndTempCopy

rem The global ANDROID_SWT always override the SWT.Jar path
if defined ANDROID_SWT set swt_path=%ANDROID_SWT%

if exist %swt_path% goto SetPath
    echo ERROR: SWT folder '%swt_path%' does not exist.
    echo Please set ANDROID_SWT to point to the folder containing swt.jar for your platform.
    goto :EOF

:SetPath
rem Finally exec the java program and end here.
REM set REMOTE_DEBUG=-Xdebug -Xrunjdwp:transport=dt_socket,server=y,suspend=y,address=8000
call %java_exe% %REMOTE_DEBUG% -Dcom.android.sdkmanager.toolsdir="%tools_dir%" -Dcom.android.sdkmanager.workdir=%work_dir% -classpath "%jar_path%;%swt_path%\swt.jar" com.android.sdkmanager.Main %*

rem EOF

Обновление (снова)

Я установил Android SDK на WinXP, работающий в виртуальном боксе, и он отлично работает. Я бы все же предпочел использовать его на Win7.