Base64 кодируют строку в VBScript

Я первоначально использовал некоторый код VBScript от Antonin Foller: Base64 Кодируют Функцию VBS и , Base64 Декодируют Функцию VBS .

сайт Ищущего Antonin, я видел, что у него был некоторый код для , заключил печатаемое кодирование в кавычки, с помощью объекта CDO.Message , таким образом, я попробовал это.

Наконец, я портировал код, упомянутый в ответе Mark's на VBScript (также использовал некоторый код от это ТАК вопрос), и использовал поток ___ StringToBinary и функции Stream_BinaryToString от сайта Antonin для получения функций, которые использовали кодирование MSXML.

я запустил быстрый тест для измерения времени кодирования для 1 500 символьных сообщений (средний размер сообщения, который я должен отправить в свой веб-сервис) через все четыре метода:

• Собственный VBScript (VBScript)
• Заключенный в кавычки Печатаемый, с помощью CDO.Message (QP)
• Заключенный в кавычки Печатаемый Двоичный файл, с помощью CDO.Message (Двоичный файл QP)
• MSXML/ADODB.Stream (MSXML)

Вот результаты:

Iterations   : 10,000
Message Size :  1,500

+-------------+-----------+
+ Method      | Time (ms) + 
+-------------+-----------+
| VBScript    |   301,391 |
+-------------+-----------+
| QP          |    12,922 |
+-------------+-----------+
| QP (Binary) |    13,953 |
+-------------+-----------+
| MSXML       |     3,312 |
+-------------+-----------+

я также контролировал использование памяти (Использование мадам для процесса cscript.exe в Windows Task Manager), в то время как тест работал. У меня нет необработанных чисел, но использование памяти и для заключенных в кавычки печатаемых и для решений MSXML были ниже решения для VBScript (7,000K для первого, вокруг 16,000K для VBScript).

я решил пойти с решением MSXML для моего драйвера. Для заинтересованных, вот код, который я использую:

base64.vbs
Function Base64Encode(sText)
    Dim oXML, oNode

    Set oXML = CreateObject("Msxml2.DOMDocument.3.0")
    Set oNode = oXML.CreateElement("base64")
    oNode.dataType = "bin.base64"
    oNode.nodeTypedValue =Stream_StringToBinary(sText)
    Base64Encode = oNode.text
    Set oNode = Nothing
    Set oXML = Nothing
End Function

Function Base64Decode(ByVal vCode)
    Dim oXML, oNode

    Set oXML = CreateObject("Msxml2.DOMDocument.3.0")
    Set oNode = oXML.CreateElement("base64")
    oNode.dataType = "bin.base64"
    oNode.text = vCode
    Base64Decode = Stream_BinaryToString(oNode.nodeTypedValue)
    Set oNode = Nothing
    Set oXML = Nothing
End Function

'Stream_StringToBinary Function
'2003 Antonin Foller, http://www.motobit.com
'Text - string parameter To convert To binary data
Function Stream_StringToBinary(Text)
  Const adTypeText = 2
  Const adTypeBinary = 1

  'Create Stream object
  Dim BinaryStream 'As New Stream
  Set BinaryStream = CreateObject("ADODB.Stream")

  'Specify stream type - we want To save text/string data.
  BinaryStream.Type = adTypeText

  'Specify charset For the source text (unicode) data.
  BinaryStream.CharSet = "us-ascii"

  'Open the stream And write text/string data To the object
  BinaryStream.Open
  BinaryStream.WriteText Text

  'Change stream type To binary
  BinaryStream.Position = 0
  BinaryStream.Type = adTypeBinary

  'Ignore first two bytes - sign of
  BinaryStream.Position = 0

  'Open the stream And get binary data from the object
  Stream_StringToBinary = BinaryStream.Read

  Set BinaryStream = Nothing
End Function

'Stream_BinaryToString Function
'2003 Antonin Foller, http://www.motobit.com
'Binary - VT_UI1 | VT_ARRAY data To convert To a string 
Function Stream_BinaryToString(Binary)
  Const adTypeText = 2
  Const adTypeBinary = 1

  'Create Stream object
  Dim BinaryStream 'As New Stream
  Set BinaryStream = CreateObject("ADODB.Stream")

  'Specify stream type - we want To save binary data.
  BinaryStream.Type = adTypeBinary

  'Open the stream And write binary data To the object
  BinaryStream.Open
  BinaryStream.Write Binary

  'Change stream type To text/string
  BinaryStream.Position = 0
  BinaryStream.Type = adTypeText

  'Specify charset For the output text (unicode) data.
  BinaryStream.CharSet = "us-ascii"

  'Open the stream And get text/string data from the object
  Stream_BinaryToString = BinaryStream.ReadText
  Set BinaryStream = Nothing
End Function