Метод ColdFusion cfc может определить свое собственное имя?

Я согласовываю w/tpryan. ColdSpring делает это очень легким. Однако вот другая альтернатива. Вместо того, чтобы анализировать отслеживание стека, можно проанализировать сам файл CFC.

<cffunction name="foo" displayname="foo" hint="this is just a test function" access="public" returntype="string">
    <cfset var test = getFunctionName(getMetaData().path, getPageContext().getCurrentLineNo()) />
    <cfreturn test />
</cffunction>

<cffunction name="getFunctionName" hint="returns the function name based on the line number" access="public" returntype="string">
    <cfargument name="filepath" type="string" required="true" />
    <cfargument name="linenum" type="any" required="true" />
    <cfset var line = "" />
    <cfset var functionName = "" />
    <cfset var i = 1 />
    <!---- loop over CFC by line ---->
    <cfloop file="#ARGUMENTS.filepath#" index="line">
        <cfif findNoCase('cffunction', line, 1)>
            <cfset functionName = line />
        </cfif>
        <cfif i EQ ARGUMENTS.linenum><cfbreak /></cfif>
        <cfset i++ />
    </cfloop>
    <!---- parse function name ---->
    <cfset functionName = REMatchNoCase("(\bname=[""|'])+[a-z]*[""|']", functionName) />
    <cfset functionName = REMatchNoCase("[""']+[a-z]*[""']", functionName[1]) />
    <cfset functionName = ReReplaceNoCase(functionName[1], "[""']", "", "all") />
    <!---- return success ---->
    <cfreturn functionName />
</cffunction>

Вышеупомянутое записано для ColdFusion 8. Добавленная поддержка CFLOOP цикличного выполнения по файлам линию за линией (и не читает весь файл в память). Я сделал несколько тестов, сравнивающих метод отслеживания стека по сравнению с парсингом файла. Оба работали одинаково хорошо на маленьком CFC, называемом непосредственно из единственного шаблона CFM. Очевидно, если у Вас есть очень большой CFCs, метод парсинга мог бы быть немного медленнее. С другой стороны, если у Вас есть большое отслеживание стека (как то, если Вы используете какую-либо из популярных платформ), затем, парсинг файла может быть быстрее.

- = Да здравствует ColdFusion = -

Таким образом, теперь 3 пути.

Если Вы используете ColdFusion 9.0 или выше существует теперь функция под названием GetFunctionCalledName (). Это возвратит то, что Вы ищете. http://help.adobe.com/en_US/ColdFusion/9.0/CFMLRef/WS7cc222be8a31a47d-6e8b7083122cebfc8f2-8000.html

ИЛИ

Используйте ColdSpring и Аспектно-ориентированное программирование (http://www.coldspringframework.org/coldspring/examples/quickstart/index.cfm?page=aop) для обработки этого для Вас.

ИЛИ

Используйте cfthrow для генерации отслеживания стека, которое имеет информацию для Вас:

<cffunction name="determineFunction" output="FALSE" access="public"  returntype="string" hint="" >
<cfset var functionName ="" />
<cfset var i = 0 />
<cfset var stackTraceArray = "" />
<cftry>
<cfthrow />
<cfcatch type="any">
    <cfset stacktraceArray = ListToArray(Replace(cfcatch.stacktrace, "at ", " | ", "All"), "|") />

    <!---Rip the right rows out of the stacktrace --->
    <cfloop index ="i" to="1" from="#ArrayLen(stackTraceArray)#" step="-1">
        <cfif not findNoCase("runFunction", stackTraceArray[i]) or FindNoCase("determineFunction", stackTraceArray[i])>
            <cfset arrayDeleteAt(stackTraceArray, i) />
        </cfif>
    </cfloop>

    <!---Whittle down the string to the func name --->
    <cfset functionName =GetToken(stacktraceArray[1], 1, ".") />
    <cfset functionName =GetToken(functionName, 2, "$")/>
    <cfset functionName =ReplaceNoCase(functionName, "func", "", "once")/>

    <cfreturn functionName />
</cfcatch>
</cftry></cffunction>

Моя рекомендация была бы использованием getFunctionCalledName, или если не на CF 9 ColdSpring, поскольку это, вероятно, купит Вас некоторые другие вещи.

Хорошо Вы могли бы попробовать это:

 <cffunction name="getFunctionName" returntype="any">
        <cfset meta =getMetaData(this)> 
        <cfreturn meta.functions[numberOfFunction].name>
    </cffunction>

Я попробовал различные вещи, и это не точно, поскольку функции, кажется, добавляются к массиву функций в обратном алфавитном порядке. Это кажется ограничением (и не решение проблемы). Я предположил бы, что некоторый собственный код Java мог быть вызван, но я испытываю необходимость для изучения этого.

Это и Это похожи на интересное чтение на связанных внутренних функциях.

Ре: другой ответ на coldspring. Я нашел это подробно статьей о функциональных метаданных с coldspring.

Связанный вопрос: Как получить название компонента, это расширяет мой в ColdFusion?

Я думал иначе, который мог работать.

Установите OnMissingMethod что-то вроде этого:

<cffunction name="onMissingMethod">
    <cfargument name="missingMethodName" type="string"> 
    <cfargument name="missingMethodNameArguments" type="struct">

    <cfset var tmpReturn = "">
    <cfset var functionToCallName = "Hidden" & Arguments.missingMethodName>
    <cfset arguments.missingMethodArguments.calledMethodName = Arguments.missingMethodName>
    <cfinvoke method="#functionToCallName#" argumentcollection="#Arguments.missingMethodArguments#" returnvariable="tmpReturn" />
    <cfreturn tmpReturn>
</cffunction>

Затем назовите каждый из обычных методов с префиксом ("Скрытым" в этом примере) и отметьте их как частных. Таким образом, мой начальный пример стал бы:

<cffunction name="HiddenisUsernameAvailable" access="private">
    <cfset logAccess(request.userid,Arguments.calledMethodName)>
    ......
</cffunction>

Теперь все вызовы будут прерваны onMissingMethod, который добавит имя метода к аргументам, которые передаются реальному методу.

Оборотные стороны, которые я вижу к этому, - то, что самоанализ больше не работает правильно, и необходимо использовать параметры, передаваемые по имени для вызывания всех функций. Если Вы не будете использовать параметры, передаваемые по имени, то args случайным образом изменит порядок в missingMethodNameArguments структуре.