Как сделать снимок экрана Активного окна в Delphi?

Это комбинирует все подходы, описанные до сих пор. Это также обрабатывает сценарии нескольких-мониторов.

Передача в виде снимка экрана, который Вы хотите, и TJpegImage, и он присвоит Ваш требуемый снимок экрана тому изображению.

///////////
uses
  Jpeg;

type  //define an ENUM to describe the possible screenshot types.
  TScreenShotType = (sstActiveWindow, sstActiveClientArea,
    sstPrimaryMonitor, sstDesktop);
///////////

procedure TfrmMain.GetScreenShot(shotType: TScreenShotType;
  var img: TJpegImage);
var
  w,h: integer;
  DC: HDC;
  hWin: Cardinal;
  r: TRect;
  tmpBmp: TBitmap;
begin
  hWin := 0;
  case shotType of
    sstActiveWindow:
      begin
        //only the active window
        hWin := GetForegroundWindow;
        dc := GetWindowDC(hWin);
        GetWindowRect(hWin,r);
        w := r.Right - r.Left;
        h := r.Bottom - r.Top;
      end;  //sstActiveWindow
    sstActiveClientArea:
      begin
        //only the active client area (active window minus title bars)
        hWin := GetForegroundWindow;
        dc := GetDC(hWin);
        GetWindowRect(hWin,r);
        w := r.Right - r.Left;
        h := r.Bottom - r.Top;
      end;  //sstActiveClientArea
    sstPrimaryMonitor:
      begin
        //only the primary monitor.  If 1 monitor, same as sstDesktop.
        hWin := GetDesktopWindow;
        dc := GetDC(hWin);
        w := GetDeviceCaps(DC,HORZRES);
        h := GetDeviceCaps(DC,VERTRES);
      end;  //sstPrimaryMonitor
    sstDesktop:
      begin
        //ENTIRE desktop (all monitors)
        dc := GetDC(GetDesktopWindow);
        w := Screen.DesktopWidth;
        h := Screen.DesktopHeight;
      end;  //sstDesktop
    else begin
      Exit;
    end;  //case else
  end;  //case

  //convert to jpg
  tmpBmp := TBitmap.Create;
  try
    tmpBmp.Width := w;
    tmpBmp.Height := h;
    BitBlt(tmpBmp.Canvas.Handle,0,0,tmpBmp.Width,
      tmpBmp.Height,DC,0,0,SRCCOPY);
    img.Assign(tmpBmp);
  finally
    ReleaseDC(hWin,DC);
    FreeAndNil(tmpBmp);
  end;  //try-finally
end;

Никто здесь не отправил хороший ответ. Решение, которое было до сих пор предложено это для взятия снимка экрана, который 'обрезается' в положении целевого окна. Что, если то окно находится позади другого и в настоящее время не представляется Операционной системой? Вот почему необходимо использовать эту функцию, представленную в Windows XP.

После быстрого Google вот некоторый пример кода: http://delphi.about.com/od/delphitips2008/qt/print_window.htm

JCL приходит на помощь еще раз..

    hwnd := GetForegroundWindow;
    Windows.GetClientRect(hwnd, r);
    JclGraphics.ScreenShot(theBitmap, 0, 0, r.Right - r.Left, r.Bottom - r.Top, hwnd);

    // use theBitmap...

Используйте GetForegroundWindow () вместо GetDesktopWindow ().

Необходимо будет сохранить дескриптор, который GetForegroundWindow () возвращают и передают сохраненное значение в ReleaseDC () - чтобы быть уверенными, что GetWindowDC () и ReleaseDC () называют точно для того же окна в случае, если активное окно изменяется между вызовами.

Ваш код мог быть намного более простым. Когда Вы выбрали, какую форму Вы хотите сохранить, попробуйте код, который я использую:

procedure SaveFormBitmapToBMPFile( AForm : TCustomForm; AFileName : string = '' );
// Copies this form's bitmap to the specified file
var
  Bitmap: TBitMap;
begin
  Bitmap := AForm.GetFormImage;
  try
    Bitmap.SaveToFile( AFileName );
  finally
    Bitmap.Free;
  end;
end;