Будет.Net 4.0 включать новый CLR или оставаться с версией 2.0

TBitmap VCL поддерживает только изображения BMP. Если вы попытаетесь загрузить в него любое другое изображение, вы получите исключение.

Чтобы загрузить JPG, вам нужно использовать TJPEGImage . Чтобы загрузить PNG, используйте вместо этого TPNGImage .

Вы можете использовать TPicture , чтобы помочь вам с этой задачей, например:

uses
 ..., Vcl.Graphics, Vcl.Imaging.jpeg, Vcl.Imaging.pngimage;

function resize2(source: string): TBitmap;
var
  Pic: TPicture;
begin
  Pic := TPicture.Create;
  try
    Pic.LoadFromFile(source);
    Result := TBitmap.Create;
    try
      if Pic.Graphic is TBitmap then
        Result.PixelFormat := TBitmap(Pic.Graphic).PixelFormat
      else
        Result.PixelFormat := pf32bit;
      Result.Width := 10;
      Result.Height := 10;
      Result.Canvas.StretchDraw(Rect(0, 0, Result.Width, Result.Height), Pic.Graphic);
    except
      Result.Free;
      raise;
    end;
  finally
    Pic.Free;
  end;
end;

procedure TAlpha.dbeditTextBoxChange(Sender: TObject);
var
  pic1: string;
  mimapa: TBitmap;
begin
  try
    pic1 := dm.TableNotes.FieldByName('PathPic').AsString;
    mimapa := resize2(pic1);
    try
      image2.Picture.Assign(mimapa);
    finally
      mimapa.Free;
    end;
    ...
  except
   ...
  end;
end;