ANTLR: существует ли простой пример?

Примечание : это ответ для ANTLR3 ! Если вы ищете пример ANTLR4 , то этот Q&A демонстрирует, как создать простой синтаксический анализатор выражений и вычислитель с использованием ANTLR4 .

Сначала вы создать грамматику. Ниже приведена небольшая грамматика, которую вы можете использовать для оценки выражений, построенных с использованием 4 основных математических операторов: +, -, * и /. Вы также можете группировать выражения, используя круглые скобки.

Обратите внимание, что эта грамматика является очень простой: она не обрабатывает унарные операторы (минус в: -1 + 9) или десятичные дроби, такие как .99 (без ведущего числа), чтобы назвать всего два недостатка. Это просто пример, вы можете поработать над собой.

Вот содержимое файла грамматики Exp.g :

grammar Exp;

/* This will be the entry point of our parser. */
eval
    :    additionExp
    ;

/* Addition and subtraction have the lowest precedence. */
additionExp
    :    multiplyExp 
         ( '+' multiplyExp 
         | '-' multiplyExp
         )* 
    ;

/* Multiplication and division have a higher precedence. */
multiplyExp
    :    atomExp
         ( '*' atomExp 
         | '/' atomExp
         )* 
    ;

/* An expression atom is the smallest part of an expression: a number. Or 
   when we encounter parenthesis, we're making a recursive call back to the
   rule 'additionExp'. As you can see, an 'atomExp' has the highest precedence. */
atomExp
    :    Number
    |    '(' additionExp ')'
    ;

/* A number: can be an integer value, or a decimal value */
Number
    :    ('0'..'9')+ ('.' ('0'..'9')+)?
    ;

/* We're going to ignore all white space characters */
WS  
    :   (' ' | '\t' | '\r'| '\n') {$channel=HIDDEN;}
    ;

(Правила синтаксического анализатора начинаются со строчной буквы, и правила лексера начинаются с заглавной буквы)

После создания грамматики вы захотите сгенерировать из нее парсер и лексер. Загрузите банку ANTLR и сохраните ее в том же каталоге, что и ваш файл грамматики.

Выполните следующую команду в своей оболочке / командной строке:

java -cp antlr-3.2.jar org.antlr.Tool Exp.g

Она не должна выдавать никаких сообщений об ошибках, а файлы ExpLexer.java , ExpParser.java и Exp.tokens теперь должны быть сгенерированы.

Чтобы проверить, все ли работает правильно, создайте этот тестовый класс:

import org.antlr.runtime.*;

public class ANTLRDemo {
    public static void main(String[] args) throws Exception {
        ANTLRStringStream in = new ANTLRStringStream("12*(5-6)");
        ExpLexer lexer = new ExpLexer(in);
        CommonTokenStream tokens = new CommonTokenStream(lexer);
        ExpParser parser = new ExpParser(tokens);
        parser.eval();
    }
}

и скомпилируйте его:

// *nix/MacOS
javac -cp .:antlr-3.2.jar ANTLRDemo.java

// Windows
javac -cp .;antlr-3.2.jar ANTLRDemo.java

, а затем запустите:

// *nix/MacOS
java -cp .:antlr-3.2.jar ANTLRDemo

// Windows
java -cp .;antlr-3.2.jar ANTLRDemo

Если все пойдет хорошо, на консоль ничего не выводится. Это означает, что синтаксический анализатор не обнаружил ошибок. Если вы измените "12 * (5-6)" на "12 * (5-6" , а затем перекомпилируете и запустите его, там должно быть напечатано следующее:

line 0:-1 mismatched input '<EOF>' expecting ')'

Хорошо, теперь мы хотим добавить немного кода Java в грамматику, чтобы синтаксический анализатор действительно делал что-то полезное. Добавить код можно, поместив { и } внутри вашей грамматики с некоторым простым кодом Java внутри него.

Но сначала: все правила синтаксического анализатора в файле грамматики должны возвращать примитив двойное значение. Вы можете сделать это, добавив , возвращающее [двойное значение] после каждого правила:

grammar Exp;

eval returns [double value]
    :    additionExp
    ;

additionExp returns [double value]
    :    multiplyExp 
         ( '+' multiplyExp 
         | '-' multiplyExp
         )* 
    ;

// ...

, которое требует небольшого объяснения: ожидается, что каждое правило вернет двойное значение. Теперь, чтобы «взаимодействовать» с возвращаемым значением double value (которое НЕ находится внутри простого блока кода Java {...} ) изнутри блока кода, вам необходимо добавьте знак доллара перед значением :

grammar Exp;

/* This will be the entry point of our parser. */
eval returns [double value]                                                  
    :    additionExp { /* plain code block! */ System.out.println("value equals: "+$value); }
    ;

// ...

Здесь ' s грамматика, но теперь с добавленным кодом Java:

grammar Exp;

eval returns [double value]
    :    exp=additionExp {$value = $exp.value;}
    ;

additionExp returns [double value]
    :    m1=multiplyExp       {$value =  $m1.value;} 
         ( '+' m2=multiplyExp {$value += $m2.value;} 
         | '-' m2=multiplyExp {$value -= $m2.value;}
         )* 
    ;

multiplyExp returns [double value]
    :    a1=atomExp       {$value =  $a1.value;}
         ( '*' a2=atomExp {$value *= $a2.value;} 
         | '/' a2=atomExp {$value /= $a2.value;}
         )* 
    ;

atomExp returns [double value]
    :    n=Number                {$value = Double.parseDouble($n.text);}
    |    '(' exp=additionExp ')' {$value = $exp.value;}
    ;

Number
    :    ('0'..'9')+ ('.' ('0'..'9')+)?
    ;

WS  
    :   (' ' | '\t' | '\r'| '\n') {$channel=HIDDEN;}
    ;

и поскольку наше правило eval теперь возвращает двойное значение, измените свой ANTLRDemo.java на этот:

import org.antlr.runtime.*;

public class ANTLRDemo {
    public static void main(String[] args) throws Exception {
        ANTLRStringStream in = new ANTLRStringStream("12*(5-6)");
        ExpLexer lexer = new ExpLexer(in);
        CommonTokenStream tokens = new CommonTokenStream(lexer);
        ExpParser parser = new ExpParser(tokens);
        System.out.println(parser.eval()); // print the value
    }
}

Снова (повторно) сгенерируйте новый лексер и синтаксического анализатора из вашей грамматики (1), скомпилируйте все классы (2) и запустите ANTLRDemo (3):

// *nix/MacOS
java -cp antlr-3.2.jar org.antlr.Tool Exp.g   // 1
javac -cp .:antlr-3.2.jar ANTLRDemo.java      // 2
java -cp .:antlr-3.2.jar ANTLRDemo            // 3

// Windows
java -cp antlr-3.2.jar org.antlr.Tool Exp.g   // 1
javac -cp .;antlr-3.2.jar ANTLRDemo.java      // 2
java -cp .;antlr-3.2.jar ANTLRDemo            // 3

, и теперь вы увидите результат выражения 12 * (5-6) , напечатанного в ваша консоль!

Опять же: это очень краткое объяснение. Я рекомендую вам просмотреть вики ANTLR и прочитать несколько руководств и / или поиграть с тем, что я только что опубликовал.

Удачи!

РЕДАКТИРОВАТЬ:

Этот пост показывает как расширить приведенный выше пример, чтобы можно было предоставить Map , которая содержит переменные в предоставленном выражении.

Чтобы этот код работал с текущей версией Antlr (июнь 2014 г.), мне нужно было внести несколько изменений. ANTLRStringStream должен стать ANTLRInputStream , возвращаемое значение необходимо изменить с parser.eval () на parser.eval (). Value , и мне нужно было удалить в конце предложение WS , потому что значения атрибутов, такие как $ channel , больше не могут появляться в действиях лексера.