Я использовал кадры в Delphi в течение многих лет, и они - одна из наиболее мощных функций VCL, но стандартное использование их, кажется, имеет некоторый риск, такой как:
Легко случайно переместить или отредактировать субкомпоненты кадра на форме хоста кадра, не понимая, что Вы 'настраиваете' с кадром - я знаю, что это не влияет на код исходного кадра, но это обычно не, что Вы хотели бы.
При работе с кадром Вы все еще подвергаетесь его субкомпонентам для визуального редактирования, даже когда тому кадру годы и не должен быть затронут.
Таким образом, я добрался до взглядов....
Существует ли способ 'сгруппировать' компоненты, таким образом, что их положения 'заблокированы'? Это было бы полезно для законченных форм, а также кадров. Часто другой код возврата разработчиков мне, где только границы формы изменились и даже они не предназначали изменения.
Есть ли какой-либо способ повернуть кадр и его компоненты в единственный компонент Delphi? Если так, внутренности кадра были бы полностью скрыты, и его useability увеличится далее.
Я интересуюсь любыми мыслями...
Brian.
Регистрация ваших фреймов в качестве компонента решает как 1., так и 2.
Но: есть несколько проблем (которые можно решить, см. ссылку на статью), из которых наиболее важна следующая:
Когда вы размещаете компоненты на своей раме, а затем Отбросьте этот фрейм как компонент в форме или фрейме Delphi, компоненты будут видны на панели структуры.
Проблема в том, что, поскольку они видны на панели структуры, вы можете удалить их, что приведет к нарушениям доступа.
Уловка, позволяющая решить эту не забыть «веточку» .
Я усвоил этот ценный урок от Рэя Конопки во время DelphiLive 2009 г.
Поскольку урок очень ценный, я написал сообщение в блоге , подробно описывающий его.
Важнейшей частью является этот небольшой фрагмент кода (подробнее в сообщении в блоге):
procedure RegisterFramesAsComponents(const Page: string; const FrameClasses: array of TFrameClass);
var
FrameClass: TFrameClass;
begin
for FrameClass in FrameClasses do
begin
RegisterComponents(Page, [FrameClass]);
RegisterSprigType(FrameClass, TComponentSprig);
end;
end;
Надеюсь, это поможет.
- jeroen
Я также столкнулся с этой проблемой при попытке использовать фреймы в качестве компонентов. Существуют различные возможности исправить очевидные проблемы, но все они подрывают принцип сокрытия информации (все подкомпоненты фрейма отображаются как опубликованные свойства, что означает, что каждый может получить к ним доступ).
Я решил это, реализовав общий компонент «управления кадром»:
unit RttiBrow.Cbde.FrameControl;
interface
uses
Classes, Controls, Forms, Messages, ExtCtrls;
type
TFrameClass = class of TFrame;
TComponentFrame = class (TFrame)
private
function GetClientHeight: Integer;
function GetClientWidth: Integer;
procedure SetClientHeight(const Value: Integer);
procedure SetClientWidth(const Value: Integer);
function GetOldCreateOrder: Boolean;
procedure SetOldCreateOrder(const Value: Boolean);
function GetPixelsPerInch: Integer;
procedure SetPixelsPerInch(const Value: Integer);
function GetTextHeight: Integer;
procedure SetTextHeight(const Value: Integer);
published
{ workarounds for IDE bug }
property ClientWidth: Integer read GetClientWidth write SetClientWidth stored False;
property ClientHeight: Integer read GetClientHeight write SetClientHeight stored False;
property OldCreateOrder: Boolean read GetOldCreateOrder write SetOldCreateOrder stored False;
property PixelsPerInch: Integer read GetPixelsPerInch write SetPixelsPerInch stored False;
property TextHeight: Integer read GetTextHeight write SetTextHeight stored False;
end;
TComponentFrame<TFrameControl: class { TControl }> = class (TComponentFrame)
private
function GetController: TFrameControl; inline;
protected
property Controller: TFrameControl read GetController;
public
constructor Create (AOwner: TComponent); override;
end;
TFrameControl<T: TFrame> = class (TWinControl)
private
FFrame: T;
function PlainFrame: TFrame;
protected
procedure CreateParams (var Params: TCreateParams); override;
property Frame: T read FFrame;
public
constructor Create (AOwner: TComponent); override;
property DockManager;
published
property Align;
property Anchors;
property BiDiMode;
property Color;
property Constraints;
property Ctl3D;
property UseDockManager default True;
property DockSite;
property DoubleBuffered;
property DragCursor;
property DragKind;
property DragMode;
property Enabled;
property Font;
property ParentBiDiMode;
property ParentBackground;
property ParentColor;
property ParentCtl3D;
property ParentDoubleBuffered;
property ParentFont;
property ParentShowHint;
property ShowHint;
property TabOrder;
property TabStop;
property Touch;
property Visible;
property OnAlignInsertBefore;
property OnAlignPosition;
property OnCanResize;
property OnConstrainedResize;
property OnDockDrop;
property OnDockOver;
property OnDragDrop;
property OnDragOver;
property OnEndDock;
property OnEndDrag;
property OnEnter;
property OnExit;
property OnGesture;
property OnGetSiteInfo;
property OnMouseActivate;
property OnMouseDown;
property OnMouseEnter;
property OnMouseLeave;
property OnMouseMove;
property OnMouseUp;
property OnResize;
property OnStartDock;
property OnStartDrag;
property OnUnDock;
end;
implementation
uses
Windows;
{ TFrameControl<T> }
constructor TFrameControl<T>.Create(AOwner: TComponent);
begin
inherited;
FFrame := T (TFrameClass (T).Create (Self));
PlainFrame.Parent := Self;
PlainFrame.Align := alClient;
end;
procedure TFrameControl<T>.CreateParams(var Params: TCreateParams);
begin
inherited;
Params.Style := Params.Style or WS_CLIPCHILDREN;
Params.ExStyle := Params.ExStyle or WS_EX_CONTROLPARENT;
end;
function TFrameControl<T>.PlainFrame: TFrame;
begin
Result := FFrame; // buggy compiler workaround
end;
{ TComponentFrame }
function TComponentFrame.GetOldCreateOrder: Boolean;
begin
Result := False;
end;
function TComponentFrame.GetPixelsPerInch: Integer;
begin
Result := 0;
end;
function TComponentFrame.GetTextHeight: Integer;
begin
Result := 0;
end;
procedure TComponentFrame.SetClientHeight(const Value: Integer);
begin
Height := Value;
end;
procedure TComponentFrame.SetClientWidth(const Value: Integer);
begin
Width := Value;
end;
procedure TComponentFrame.SetOldCreateOrder(const Value: Boolean);
begin
end;
procedure TComponentFrame.SetPixelsPerInch(const Value: Integer);
begin
end;
procedure TComponentFrame.SetTextHeight(const Value: Integer);
begin
end;
function TComponentFrame.GetClientHeight: Integer;
begin
Result := Height;
end;
function TComponentFrame.GetClientWidth: Integer;
begin
Result := Width;
end;
{ TComponentFrame<TFrameControl> }
constructor TComponentFrame<TFrameControl>.Create(AOwner: TComponent);
begin
inherited;
Assert (AOwner <> nil);
Assert (AOwner.InheritsFrom (TFrameControl));
end;
function TComponentFrame<TFrameControl>.GetController: TFrameControl;
begin
Result := TFrameControl (Owner);
end;
end.
В этом классе добавление кадра в качестве компонента становится двухэтапным процессом:
// frame unit
type
TFilteredList = class;
TFrmFilteredList = class (TComponentFrame<TFilteredList>)
// lots of published sub-components and event methods like this one:
procedure BtnFooClick(Sender: TObject);
end;
TFilteredList = class (TFrameControl<TFrmFilteredList>)
private
procedure Foo;
public
// the component's public interface
published
// the component's published properties
end;
procedure Register;
...
procedure Register;
begin
RegisterComponents ('CBDE Components', [TFilteredList]);
end;
procedure TFrmFilteredList.BtnFooClick(Sender: TObject);
begin
Controller.Foo;
end;
procedure TFilteredList.Foo;
begin
end;
...
При использовании этого подхода пользователь вашего компонента выигрывал Не вижу ваших подкомпонентов.
Да, просто зарегистрируйте их как компоненты. :-)
Разработайте свой фрейм нормально и после этого зарегистрируйте его. Также убедитесь, что у вас нет нежелательных зависимостей от различных блоков, поскольку они связаны, когда используется ваш "компонент". Также вы можете добавить свойства published
, чтобы позже использовать их в инспекторе объектов. Смотрите, например, следующий код, сгенерированный IDE (см. также мои комментарии):
unit myUnit;
uses
...
type
TmyComp = class(TFrame) //set your frame name to be the name your component
ToolBar1: TToolBar; //different components added in the form designer
aliMain: TActionList;
...
published //this section is added by hand
property DataSource: TDataSource read FDataSource write SetDataSource; //some published properties added just for exemplification
property DefFields: string read FDefFields write SetDefFields;
...
end;
procedure Register; //added by hand
implementation
{$R *.DFM}
procedure Register;
begin
RegisterComponents('MyFrames', [TmyComp]); //register the frame in the desired component category
end;
Скомпилируйте вышеуказанное в пакет по вашему выбору, установите его и проверьте палитру компонентов. :-)
HTH
Я почти всегда создаю экземпляры фреймов в коде. Это легко и до сих пор хорошо работало для меня.