Как я могу выполнить итерации по recordset в рамках хранимой процедуры?
Я должен выполнить итерации по recordset из хранимой процедуры и выполнить другую хранимую процедуру с помощью каждого поля в качестве аргументов. Я не могу завершить это повторение в коде. Я нашел образцы в Интернете, но они все, кажется, имеют дело со счетчиком. Я не уверен, включила ли моя проблема счетчик. Мне нужен T-SQL, эквивалентный из foreach
В настоящее время моя первая хранимая процедура хранит свой recordset во временной таблице, #mytemp. Я предполагаю, что назову вторичную хранимую процедуру как это:
while (something)
execute nameofstoredprocedure arg1, arg2, arg3
end
2 ответа
Вам нужно создать курсор для циклического просмотра набора записей.
Пример таблицы:
CREATE TABLE Customers
(
CustomerId INT NOT NULL PRIMARY KEY IDENTITY(1,1)
,FirstName Varchar(50)
,LastName VARCHAR(40)
)
INSERT INTO Customers VALUES('jane', 'doe')
INSERT INTO Customers VALUES('bob', 'smith')
Курсор:
DECLARE @CustomerId INT, @FirstName VARCHAR(30), @LastName VARCHAR(50)
DECLARE @MessageOutput VARCHAR(100)
DECLARE Customer_Cursor CURSOR FOR
SELECT CustomerId, FirstName, LastName FROM Customers
OPEN Customer_Cursor
FETCH NEXT FROM Customer_Cursor INTO
@CustomerId, @FirstName, @LastName
WHILE @@FETCH_STATUS = 0
BEGIN
SET @MessageOutput = @FirstName + ' ' + @LastName
RAISERROR(@MessageOutput,0,1) WITH NOWAIT
FETCH NEXT FROM Customer_Cursor INTO
@CustomerId, @FirstName, @LastName
END
CLOSE Customer_Cursor
DEALLOCATE Customer_Cursor
Вот ссылка на MSDN о том, как их создавать.
http://msdn.microsoft.com/en-us/library/ms180169.aspx
Вот почему я использовал Raise Error вместо PRINT для вывода.
http://structuredsight.com/2014/11/24/wait-wait-dont-tell-me-on-second-gotit/
попробуйте это (цикл без курсора):
CREATE TABLE #Results (RowID int identity(1,1), Col1 varchar(5), Col2 int, ... )
DECLARE @Current int
,@End int
DECLARE @Col1 varchar(5)
,@Col2 int
,...
--you need to capture the result set from the primary stored procedure
INSERT INTO #Results
(Col1, COl2,...)
EXEC nameofstoredprocedure_1 arg1, arg2, arg3
SELECT @End=@@ROWCOUNT,@Current=0
--process each row in the result set
WHILE @Current<@End
BEGIN
SET @Current=@Current+1
SELECT
@Col1=COl1, @Col2=Col2
FROM #Results
WHERE RowID=@Current
--call the secondary procedure for each row
EXEC nameofstoredprocedure_2 @Col1, @Col2,...
END
рабочий пример:
CREATE PROCEDURE nameofstoredprocedure_1
(@arg1 int, @arg2 int, @arg3 int)
AS
SELECT 'AAA',@arg1 UNION SELECT 'BBB',@arg2 UNION SELECT 'CCC',@arg3
GO
CREATE PROCEDURE nameofstoredprocedure_2
(@P1 varchar(5), @P2 int)
AS
PRINT '>>'+ISNULL(@P1,'')+','+ISNULL(CONVERT(varchar(10),@P2),'')
GO
CREATE TABLE #Results (RowID int identity(1,1), Col1 varchar(5), Col2 int)
DECLARE @Current int
,@End int
DECLARE @Col1 varchar(5)
,@Col2 int
INSERT INTO #Results
(Col1, COl2)
EXEC nameofstoredprocedure_1 111, 222, 333
SELECT @End=@@ROWCOUNT,@Current=0
WHILE @Current<@End
BEGIN
SET @Current=@Current+1
SELECT
@Col1=COl1, @Col2=Col2
FROM #Results
WHERE RowID=@Current
EXEC nameofstoredprocedure_2 @Col1, @Col2
END
ВЫХОД:
(3 row(s) affected)
>>AAA,111
>>BBB,222
>>CCC,333