Для каждого узла "агентства" я должен найти "stmt" элементы, которые имеют тот же key1, key2, key3 значения и производят всего один "stmt" узел со значениями "коммуникации" и "prem", суммированными вместе. Для любых "stmt" элементов в том "агентстве", которые не соответствуют никаким другим "stmt" элементам на основе key1, key2 и key3, я должен произвести их, как. Таким образом, после преобразования первый узел "агентства" только имел бы два "stmt" узла (один суммированный), и второй узел "агентства" будет передан, как то, потому что ключи не соответствуют. XSLT 1.0 или 2,0 решения в порядке..., хотя моя таблица стилей в настоящее время 1.0. Обратите внимание, что узлы агентства могли иметь любое число "stmt" элементов, которые имеют соответствие ключам, которые должны быть сгруппированы и суммированы и любое число, которые не делают.
<statement>
<agency>
<stmt>
<key1>1234</key1>
<key2>ABC</key2>
<key3>15.000</key3>
<comm>75.00</comm>
<prem>100.00</prem>
</stmt>
<stmt>
<key1>1234</key1>
<key2>ABC</key2>
<key3>15.000</key3>
<comm>25.00</comm>
<prem>200.00</prem>
</stmt>
<stmt>
<key1>1234</key1>
<key2>ABC</key2>
<key3>17.50</key3>
<comm>25.00</comm>
<prem>100.00</prem>
</stmt>
</agency>
<agency>
<stmt>
<key1>5678</key1>
<key2>DEF</key2>
<key3>15.000</key3>
<comm>10.00</comm>
<prem>20.00</prem>
</stmt>
<stmt>
<key1>5678</key1>
<key2>DEF</key2>
<key3>17.000</key3>
<comm>15.00</comm>
<prem>12.00</prem>
</stmt>
</agency>
И решение XSLT 2.0 :
<xsl:stylesheet version="2.0"
xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
xmlns:xs="http://www.w3.org/2001/XMLSchema"
exclude-result-prefixes="xs"
>
<xsl:output omit-xml-declaration="yes" indent="yes"/>
<xsl:template match="node()|@*">
<xsl:copy>
<xsl:apply-templates select="node()|@*"/>
</xsl:copy>
</xsl:template>
<xsl:template match="agency">
<agency>
<xsl:for-each-group select="stmt" group-by=
"concat(key1, '+', key2, '+', key3)">
<stmt>
<xsl:copy-of select=
"current-group()[1]/*[starts-with(name(),'key')]"/>
<comm>
<xsl:value-of select="sum(current-group()/comm)"/>
</comm>
<prem>
<xsl:value-of select="sum(current-group()/prem)"/>
</prem>
</stmt>
</xsl:for-each-group>
</agency>
</xsl:template>
</xsl:stylesheet>
В XSLT 1.0 используйте метод Мюнчи для группировки (с составным ключом).
Это преобразование :
<xsl:stylesheet version="1.0"
xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
<xsl:output omit-xml-declaration="yes" indent="yes"/>
<xsl:key name="kStmtByKeys" match="stmt"
use="concat(generate-id(..), key1, '+', key2, '+', key3)"/>
<xsl:template match="node()|@*">
<xsl:copy>
<xsl:apply-templates select="node()|@*"/>
</xsl:copy>
</xsl:template>
<xsl:template match="agency">
<agency>
<xsl:for-each select=
"stmt[generate-id()
=
generate-id(key('kStmtByKeys',
concat(generate-id(..), key1, '+', key2, '+', key3)
)[1]
)
]
">
<xsl:variable name="vkeyGroup" select=
"key('kStmtByKeys', concat(generate-id(..), key1, '+', key2, '+', key3))"/>
<stmt>
<xsl:copy-of select="*[starts-with(name(), 'key')]"/>
<comm>
<xsl:value-of select="sum($vkeyGroup/comm)"/>
</comm>
<prem>
<xsl:value-of select="sum($vkeyGroup/prem)"/>
</prem>
</stmt>
</xsl:for-each>
</agency>
</xsl:template>
</xsl:stylesheet>
при применении к предоставленному XML-документу дает желаемый результат :
<statement>
<agency>
<stmt>
<key1>1234</key1>
<key2>ABC</key2>
<key3>15.000</key3>
<comm>100</comm>
<prem>300</prem>
</stmt>
<stmt>
<key1>1234</key1>
<key2>ABC</key2>
<key3>17.50</key3>
<comm>25</comm>
<prem>100</prem>
</stmt>
</agency>
<agency>
<stmt>
<key1>5678</key1>
<key2>DEF</key2>
<key3>15.000</key3>
<comm>10</comm>
<prem>20</prem>
</stmt>
<stmt>
<key1>5678</key1>
<key2>DEF</key2>
<key3>17.000</key3>
<comm>15</comm>
<prem>12</prem>
</stmt>
</agency>
</statement>
<?xml version="1.0" encoding="utf-8"?>
<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform" xmlns:msxsl="urn:schemas-microsoft-com:xslt" exclude-result-prefixes="msxsl">
<xsl:output method="xml" indent="yes"/>
<xsl:template match="/|*">
<xsl:copy>
<xsl:apply-templates select="*" />
</xsl:copy>
</xsl:template>
<xsl:template match="stmt">
<xsl:variable name="stmtGroup" select="../stmt[(key1=current()/key1) and (key2=current()/key2) and (key3=current()/key3)]" />
<xsl:if test="generate-id()=generate-id($stmtGroup[1])">
<xsl:copy>
<key1>
<xsl:value-of select="key1"/>
</key1>
<key2>
<xsl:value-of select="key2"/>
</key2>
<key3>
<xsl:value-of select="key3"/>
</key3>
<comm>
<xsl:value-of select="format-number(sum($stmtGroup/comm), '#.00')"/>
</comm>
<prem>
<xsl:value-of select="format-number(sum($stmtGroup/prem), '#.00')"/>
</prem>
</xsl:copy>
</xsl:if>
</xsl:template>
</xsl:stylesheet>