Я могу сделать что-то как следующее в Perl?
foreach (@tokens) {
if (/foo/){
# simple case, I can act on the current token alone
# do something
next;
}
if (/bar/) {
# now I need the next token, too
# I want to read/consume it, advancing the iterator, so that
# the next loop iteration will not also see it
my $nextToken = .....
# do something
next;
}
}
Обновление: Мне нужно это в Perl, но для пользы любопытства: другие языки имеют аккуратный синтаксис для этого?
Должны ли вы использовать цикл для
? Скопируйте оригинал и «потребляйте» его с помощью shift
:
use strict;
use warnings;
my @original = 'a' .. 'z'; # Original
my @array = @original; # Copy
while (my $token = shift @array) {
shift @array if $token =~ /[nr]/; # consumes the next element
print $token;
}
# prints 'abcdefghijklmnpqrtuvwxyz' ('s' and 'o' are missing)
Начиная с Perl 5.12, each стал более гибким, работая также с массивами:
use 5.012;
use warnings;
my @tokens = 'a' .. 'z';
while (my ($i, $val) = each @tokens) {
if ($val =~ m/[aeiou]/) {
($i, $val) = each @tokens; # get next token after a vowel
print $val;
}
}
# => bfjpv
Одна оговорка с each
, помните, что итератор является глобальным и не сбрасывается, если вы выходите из цикла.
Например:
while (my ($i, $val) = each @tokens) {
print $val;
last if $i == 12;
}
# => abcdefghijklm
my ($i, $val) = each @tokens;
say "Now at => $val ($i)"; # Now at => n (13)
Поэтому используйте keys
или values
для ручного сброса итератора:
keys @tokens; # resets iterator
($i, $val) = each @tokens;
say "Now at => $val ($i)"; # Now at => a (0)
Не с помощью цикла foreach
. Вы можете использовать цикл for
в стиле C:
for (my $i = 0; $i <= $#tokens; ++$i) {
local $_ = $tokens[$i];
if (/foo/){
next;
}
if (/bar/) {
my $nextToken = $tokens[++$i];
# do something
next;
}
}
Вы также можете использовать что-то вроде Array::Iterator. Я оставлю эту версию в качестве упражнения для читателя :-)
.