Используйте vbscript для изменения текстового файла

Это был бы мой псевдоалгоритм для решения этой проблемы:

(Я скорее научу вас своим мыслям о том, как я могу решить эту проблему, чем предоставить сам код)

1. Сделать файл используемым в качестве параметра (чтобы он может быть гибким) или создать папку «спулер», которую эта программа проверяет на наличие нового содержимого при запуске, например «Входящие» для почты. Тогда вам также понадобится «Исходящие». Таким образом, вы можете обрабатывать файлы по мере их поступления, не зная, как они названы, и перемещать их в «Исходящие» при обработке.

2. Сделайте простой "конфигурационный" файл и для этой программы. Каждая строка может представлять «фильтр», и позже вы можете добавить действия к строкам, если это необходимо.

   7999 удалить

   6999 удалить

   5442 удалить

   как в [шаблон] [действие]

3. Теперь, после считывания конфигурации в массив «ключей», затем проверьте «Входящие» на наличие файлов . Для каждого файла обработайте его набором ключей.

4. Обработка файла "XXXXXXXXX.log" (или любого другого имени) Загрузите все строки, если их не слишком много, или строку чтения, чтобы захватить одну (в зависимости от производительности и использования памяти)

5. Для каждой строки возьмите первые 4 буквы из строки ...

Теперь нам понадобится строка для синтаксического анализа:

sLine = left(readline(input filestream), 4) 

, поскольку нам нужны только первые 4 символа, чтобы решить, нужно ли нам ее сохранить.

Если эта «sLine» (строка) находится в нашем массиве фильтров / шаблонов, то у нас есть совпадение… выполните то действие, которое мы настроили (в вашей текущей настройке - строка delete = ignore).

6а. Если игнорировать, перейдите к следующей строке в текстовом файле, перейдите к # 7

6b. Если в массиве шаблонов совпадений нет, нам нужно сохранить строку. Запишите это в поток OUTPUT.

7. Если больше строк, NEXT (goto # 5)

8. Закройте входной и выходной файл.

9. Удалить / переместить входной файл из папки «Входящие» (возможно, для резервного копирования?)

10. Если в каталоге [входящие] будет больше файлов, затем выполните синтаксический анализ ... перейдите к # 4

Это не просто VBSCRIPT, а идея алгоритма Ann для любой язык ...

Я надеюсь, что вы сможете увидеть в нем мою идею, иначе вы просто прокомментируете это, и я постараюсь уточнить его. Надеюсь, я дал вам отличный ответ.

Я думаю, что это сработает (но я не настолько хорош в VBS, поэтому никаких обещаний):

Set objFS = CreateObject("Scripting.FileSystemObject")
strFile = "c:\temp\file.100621"
Set objFile = objFS.OpenTextFile(strFile)
Dim cachedLine
Do Until objFile.AtEndOfStream
    strLine = objFile.ReadLine

    If Len(cachedLine) > 0 And InStr(strLine,"6999") = 1 Then
         WScript.Echo cachedLine        
    End If
    cachedLine = ""

    If InStr(strLine,"5442") = 1 Then
        cachedLine = strLine
    Else
        If InStr(strLine,"6999") = 1 Or InStr(strLine,"7999") = 1 Then
            ' do nothing
        Else
            WScript.Echo strLine        
        End If
    End If     
Loop

Обратите внимание, что я думаю, вы проверяли, содержат ли строки числа где-нибудь, но вы сказали что правило было, если они начинали с чисел, поэтому я делаю <> 1 , а не > 0 .

Хорошо, вот последний скрипт, великолепно собранный Tester101. Этот сценарий удаляет строки, которые не нужны, как описано выше. Он также имеет дело с переводом строки, который находится в конце каждой строки (мне неизвестно)

Select Case Wscript.Arguments.Count
case 1:
    strInput = GetFile(WScript.Arguments(0))
    RemoveUnwantedLines strInput, strInput
    RemoveBlankLines strInput
case 2:
    strInput = GetFile(WScript.Arguments(0))
    strOutput = Wscript.Arguments(1)
    RemoveUnwantedLines strInput, strOutput
    RemoveBlankLines strOutput
End Select

Function GetFile(strDirectory)
Set objFSO = CreateObject("Scripting.FileSystemObject")
Set objFolder = objFSO.GetFolder(strDirectory)
dateLastModified = Null
strFile = ""
For Each objFile in objFolder.Files
    If IsNull(dateLastModified) Then
        dateLastModified = objFile.DateLastModified
        strFile = objFile.Path
    ElseIf dateLastModified < objFile.DateLastModified Then
        dateLastModified = objFile.DateLastModified
        strFile = objFile.Path
    End If
Next
GetFile = strFile
End Function

Sub RemoveUnwantedLines(strInputFile, strOutputFile)
    'Open the file for reading.
    Set objFile = CreateObject("Scripting.FileSystemObject").OpenTextFile(strInputFile,1)
    'Read the entire file into memory.
    strFileText = objFile.ReadAll
    'Close the file.
     objFile.Close
    'Split the file at the new line character. *Use the Line Feed character (Char(10))
    arrFileText = Split(strFileText,Chr(10))
    'Open the file for writing.
    Set objFile = CreateObject("Scripting.FileSystemObject").OpenTextFile(strOutputFile,2,true)
    'Loop through the array of lines looking for lines to keep.
    For i = LBound(arrFileText) to UBound(arrFileText)
        'If the line is not blank process it.
        If arrFileText(i) <> "" Then
            'If the line starts "5442", see if the next line is "6999".
            If Left(arrFileText(i),4) = "5442" Then
                'Make sure the next line exists (Don't want an out of bounds exception).
                If i + 1 <= UBound(arrFileText)Then
                    'If the next line is not "6999" 
                    If Left(arrFileText(i + 1), 4) <> "6999" Then
                        'Write the "5442" line to the file.
                        objFile.WriteLine(arrFileText(i))
                    End If
                Else
                    'If the next line does not exist, write the "5442" line to the file (without a new line).
                    objFile.WriteLine(arrFileText(i))
                End If              
            'If the line does not start with "6999" and the line does not start with "7999".
            Elseif Left(arrFileText(i),4) <> "6999"  AND Left(arrFileText(i),4) <> "7999" Then
                'Write the line to the file.
                objFile.WriteLine(arrFileText(i))
            End If
        End If
Next
    'Close the file.
objFile.Close
Set objFile = Nothing
End Sub

Sub RemoveBlankLines(strInputFile)
Set objFile = CreateObject("Scripting.FileSystemObject").OpenTextFile(strInputFile,1)
    'Read the entire file into memory.
strFileText = objFile.ReadAll
    'Close the file.
objFile.Close
    'Split the file at the new line character.
arrFileText = Split(strFileText,VbNewLine)
Set objFile = CreateObject("Scripting.FileSystemObject").OpenTextFile(strInputFile,2,true)
    'Loop through the array of lines looking for lines to keep.
For i = LBound(arrFileText) to UBound(arrFileText)
        'If the line is not blank.
    if arrFileText(i) <> "" Then
            'If there is another element.
        if i + 1 <= UBound(arrFileText) Then    
                'If the next element is not blank.
            if arrFileText(i + 1) <> "" Then
                    'Write the line to the file.
                objFile.WriteLine(arrFileText(i))
            Else
                    'Write the line to the file (Without a blank line).
                objFile.Write(arrFileText(i))
            End If
        Else
                'Write the line to the file (Without a blank line).
            objFile.Write(arrFileText(i))
        End If
    End If
Next
'Close the file.
objFile.Close
Set objFile = Nothing
End Sub