Mixin или реализация Trait в AS3?

Нулевые решения, представленные на этом, поэтому я рассмотрел несколько методов. Есть примеси стилей сценария ECMA путем добавления методов, определенных для других объектов, к прототипу базовых объектов. Но это означает, что преимущества статической типизации исчезли.

Я искал решение, которое не обошло бы систему статических типов. Я знал, что ASMock использовал инъекцию байт-кода для создания прокси-классов. Я изучал ASMock в течение последних нескольких дней и придумал возможное решение, реализованное путем создания класса со скомпонованными классами (посредством внедрения байт-кода).

С точки зрения пользователей это включает определение вашего объекта, который использует миксины через множество интерфейсов:

public interface Person extends RoomObject, Moveable

public interface RoomObject
{
    function joinRoom(room:Room):void
    function get room():Room
}

public interface Moveable
{
    function moveTo(location:Point):void
    function get location():Point 
}

Затем вы определяете классы для представления этих интерфейсов:

public class MoveableImpl implements Moveable
{
    private var _location:Point = new Point() 
    public function get location():Point { return _location }

    public function move(location:Point):void
    {
        _location = location.clone()
    }
}

public class RoomObjectImpl implements RoomObject
{   
    private var _room:Room
    public function get room():Room { return _room }

    public function joinRoom(room:Room):void
    {
        _room = room
    }
}

В нормальной ситуации, когда вы хотите составить классы, вы должны написать:

public class PersonImpl implements Person
{
    private var _roomObject:RoomObject = new RoomObjectImpl()

    private var _moveable:Moveable = new MoveableImpl()

    public function get room():Room { return _roomObject.room }

    public function joinRoom(room:Room):void { _roomObject.joinRoom(room) }

    public function get location():Point { return _moveable.location }

    public function move(location:Point):void { _moveable.move(location) }
}

Это легко написать с помощью кода благодаря регулярной структуре. И это именно то, что делает мое решение, внедряя эквивалентный байт-код в новый класс. С помощью этой системы внедрения байт-кода мы можем создать объект Person следующим образом:

public class Main
{
    private var mixinRepo:MixinRepository = new MixinRepository()

    public function Main()
    {
        with(mixinRepo)
        {
            defineMixin(RoomObject, RoomObjectImpl) // associate interfaces with concreate classes
            defineMixin(Moveable, MoveableImpl)
            defineBase(Person)
            prepare().completed.add(testMixins) // the injection is a async process, just liek in ASMock
        }
    }

    private function testMixins():void
    {
        var person:Person = mixinRepo.create(Person)
        var room:Room = new Room('room you can play in')

        person.joinRoom(room)
        trace('person.room:', person.room)

        person.move(new Point(1, 2))
        trace('person.location:', person.location)
    }
}

На данный момент эта система является доказательством концепции и поэтому является очень простой и хрупкой.Но он показывает, что можно приблизиться к системе стилей примесей / свойств Scala к AS3. Я создал проект на github для хранения кода, если кто-то заинтересован в запуске решения и пытается понять, как это было сделано.

Более полный пример приведен в wiki проекта .