Обнаружьте нажимают на URL in RichEdit
Я пытаюсь обновить RichEdit так, чтобы он обнаружил URL и позволил нажать на него для открытия в браузере. Обнаружение URL легко, я просто использую следующий код из http://www.scalabium.com/faq/dct0146.htm
mask := SendMessage(MNote.Handle, EM_GETEVENTMASK, 0, 0);
SendMessage(MNote.Handle, EM_SETEVENTMASK, 0, mask or ENM_LINK);
SendMessage(MNote.Handle, EM_AUTOURLDETECT, Integer(True), 0);
но вторая часть не работает на меня. Они дают следующий код для получения сообщения EN_LINK и обработки его:
type
TForm1 = class(TForm)
protected
procedure WndProc(var Message: TMessage); override;
end;
...
procedure TForm1.WndProc(var Message: TMessage);
var
p: TENLink;
strURL: string;
begin
if (Message.Msg = WM_NOTIFY) then
begin
if (PNMHDR(Message.LParam).code = EN_LINK) then
begin
p := TENLink(Pointer(TWMNotify(Message).NMHdr)^);
if (p.msg = WM_LBUTTONDOWN) then
begin
SendMessage(RichEdit1.Handle, EM_EXSETSEL, 0, LongInt(@(p.chrg)));
strURL := RichEdit1.SelText;
ShellExecute(Handle, 'open', PChar(strURL), 0, 0, SW_SHOWNORMAL);
end
end
end;
inherited;
end;
Когда я запускаю программу, URL обнаруживается, но нажатие на него ничего не делает. Используя отладку я узнал то сообщение. Сообщение = WM_NOTIFY не верен, когда я нажимаю на URL. Я затем пытался переопределить WndProc TRichEdit, но результатом является то же. Какие-либо предложения?
2 ответа
Создайте подкласс свойства WindowProc RichEdit и найдите сообщение CN_NOTIFY, например:
type
TForm1 = class(TForm)
RichEdit1: TRichEdit;
procedure FormCreate(Sender: TObject);
private
PrevRichEditWndProc: TWndMethod;
procedure RichEditWndProc(var Message: TMessage);
procedure SetRichEditMasks;
end;
procedure TForm1.FormCreate(Sender: TObject);
begin
PrevRichEditWndProc := RichEdit1.WindowProc;
RichEdit1.WindowProc := RichEditWndProc;
SetRichEditMasks;
end;
procedure TForm1.SetRichEditMasks;
var
mask: Longint;
begin
mask := SendMessage(RichEdit1.Handle, EM_GETEVENTMASK, 0, 0);
SendMessage(RichEdit1.Handle, EM_SETEVENTMASK, 0, mask or ENM_LINK);
SendMessage(RichEdit1.Handle, EM_AUTOURLDETECT, 1, 0);
end;
procedure TForm1.RichEditWndProc(var Message: TMessage);
begin
PrevRichEditWndProc(Message);
case Message.Msg of
CN_NOTIFY:
begin
if (TWMNotify(Message).NMHdr^.code = EN_LINK) then
begin
with PENLink(Message.LParam)^ do
begin
if (msg = WM_LBUTTONDOWN) then
begin
SendMessage(RichEdit1.Handle, EM_EXSETSEL, 0, LongInt(@chrg));
ShellExecute(Handle, 'open', PChar(RichEdit1.SelText), 0, 0, SW_SHOWNORMAL);
end;
end;
end;
end;
CM_RECREATEWND:
begin
SetRichEditMasks;
end;
end;
end;
Вы пробовали это с урезанным приложением, чтобы убедиться, что что-то другое в вашей программе не вызывает проблем? Я выполнил шаги с этого веб-сайта в Delphi 2009, и щелчок по URL работал нормально.