Какая фиксация имеет этот блоб?
Это называется Object Destructuring и присваивает значения путем «сопоставления» возвращаемого значения (либо объекта, либо массива).
2 ответа
Оба из следующих сценариев берут SHA1 блоба в качестве первого аргумента, и после него, дополнительно, любые аргументы это git log поймет. Например. --all искать во всех ответвлениях вместо просто текущего, или -g искать в том, чтобы повторно пороть, или независимо от того, что Вы полагаете.
Здесь это как сценарий оболочки – коротко и сладко, но медленно:
#!/bin/sh
obj_name="$1"
shift
git log "$@" --pretty=format:'%T %h %s' \
| while read tree commit subject ; do
if git ls-tree -r $tree | grep -q "$obj_name" ; then
echo $commit "$subject"
fi
done
И оптимизированная версия в Perl, все еще довольно коротком но намного быстрее:
#!/usr/bin/perl
use 5.008;
use strict;
use Memoize;
my $obj_name;
sub check_tree {
my ( $tree ) = @_;
my @subtree;
{
open my $ls_tree, '-|', git => 'ls-tree' => $tree
or die "Couldn't open pipe to git-ls-tree: $!\n";
while ( <$ls_tree> ) {
/\A[0-7]{6} (\S+) (\S+)/
or die "unexpected git-ls-tree output";
return 1 if $2 eq $obj_name;
push @subtree, $2 if $1 eq 'tree';
}
}
check_tree( $_ ) && return 1 for @subtree;
return;
}
memoize 'check_tree';
die "usage: git-find-blob <blob> [<git-log arguments ...>]\n"
if not @ARGV;
my $obj_short = shift @ARGV;
$obj_name = do {
local $ENV{'OBJ_NAME'} = $obj_short;
`git rev-parse --verify \$OBJ_NAME`;
} or die "Couldn't parse $obj_short: $!\n";
chomp $obj_name;
open my $log, '-|', git => log => @ARGV, '--pretty=format:%T %h %s'
or die "Couldn't open pipe to git-log: $!\n";
while ( <$log> ) {
chomp;
my ( $tree, $commit, $subject ) = split " ", $_, 3;
print "$commit $subject\n" if check_tree( $tree );
}
Я думал, что это будет обычно полезной вещью иметь, таким образом, я описал немного сценария жемчуга, чтобы сделать это:
#!/usr/bin/perl -w
use strict;
my @commits;
my %trees;
my $blob;
sub blob_in_tree {
my $tree = $_[0];
if (defined $trees{$tree}) {
return $trees{$tree};
}
my $r = 0;
open(my $f, "git cat-file -p $tree|") or die $!;
while (<$f>) {
if (/^\d+ blob (\w+)/ && $1 eq $blob) {
$r = 1;
} elsif (/^\d+ tree (\w+)/) {
$r = blob_in_tree($1);
}
last if $r;
}
close($f);
$trees{$tree} = $r;
return $r;
}
sub handle_commit {
my $commit = $_[0];
open(my $f, "git cat-file commit $commit|") or die $!;
my $tree = <$f>;
die unless $tree =~ /^tree (\w+)$/;
if (blob_in_tree($1)) {
print "$commit\n";
}
while (1) {
my $parent = <$f>;
last unless $parent =~ /^parent (\w+)$/;
push @commits, $1;
}
close($f);
}
if (!@ARGV) {
print STDERR "Usage: git-find-blob blob [head ...]\n";
exit 1;
}
$blob = $ARGV[0];
if (@ARGV > 1) {
foreach (@ARGV) {
handle_commit($_);
}
} else {
handle_commit("HEAD");
}
while (@commits) {
handle_commit(pop @commits);
}
Я подниму это на GitHub, когда я возвращусь домой этим вечером.
Обновление: похоже, что кто-то уже сделал это. Тот использует то же общее представление, но детали отличаются, и реализация намного короче. Я не знаю, который был бы быстрее, но производительность является, вероятно, не беспокойством здесь!
Обновление 2: Если это имеет значение моя реализация является порядками величины быстрее, специально для большого репозитория. Это git ls-tree -r действительно вред.
Обновление 3: Я должен отметить, что моя производительность комментирует выше, относятся к реализации, которую я связал выше в первом Обновлении. Реализация Aristotle работает сравнительно к моей. Больше деталей в комментариях для тех, кому любопытно.